0 BEGIN PGM 10005_FR MM 
1 ;Fraisage et tournage de pièce
2 ;
3 ;Définition de la pièce brute comme cylindre
4 BLK FORM CYLINDER Z R60 L100 DIST+1
5 ;
6 ;Activation du point de référence
7 CYCL DEF 247 BEZUGSPUNKT SETZEN ~
   Q339=+2    ;BEZUGSPUNKT-NUMMER
8 ;
9 ;Ébauchage par tournage extérieur
10 ;Appel de l'outil de tournage pour ébauchage
11 TOOL CALL "TURN_ROUGH"
12 ;
13 ;Appel du sous-programme Mode tournage
14 CALL LBL "TURN"
15 ;Appel du sous-programme Approche de la position de sécurité
16 CALL LBL "SAFE"
17 ;
18 ;Configurer le tournage
19 CYCL DEF 800 KOORD.-SYST.ANPASSEN ~
   Q497=+0    ;PRAEZESSIONSWINKEL ~
    Q498=+0    ;WERKZEUG UMKEHREN ~
    Q530=+0    ;ANGESTELLTE BEARB. ~
    Q531=+0    ;ANSTELLWINKEL ~
    Q532=+750  ;VORSCHUB ~
    Q533=+0    ;VORZUGSRICHTUNG ~
    Q535=+3    ;EXZENTERDREHEN ~
    Q536=+0    ;EXZENTR. OHNE STOPP
20 ;
21 ;Définir une vitesse de coupe constante et une
22 ;vitesse de rotation maximale
23 FUNCTION TURNDATA SPIN VCONST:ON VC:400 SMAX800
24 ;
25 ;Remettre l'axe de pivotement à zéro et
26 ;activer la broche de tournage
27 L  A+0 R0 FMAX M303
28 ;
29 ;Faire tourner le plan
30 CYCL DEF 821 ABSATZ PLAN ~
   Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q493=+0    ;KONTURENDE DURCHMESSER ~
    Q494=+0    ;KONTURENDE Z ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0    ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q506=+0    ;KONTURGLAETTUNG
31 L  X+122  Y+0 R0 FMAX ;Pré-positionnement
32 L  Z+10 R0 FMAX ;Pré-positionnement
33 L  Z+2 R0 F0.5 M99 ;Approche de la hauteur de départ et appel du cycle
34 ;
35 ;Tourner sur la longueur
36 CYCL DEF 811 ABSATZ LAENGS ~
   Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q493=+117  ;KONTURENDE DURCHMESSER ~
    Q494=-80   ;KONTURENDE Z ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.2  ;AUFMASS DURCHMESSER ~
    Q484=+0    ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q506=+0    ;KONTURGLAETTUNG
37 L  X+122  Y+0 R0 FMAX ;Pré-positionnement
38 L  Z+10 R0 FMAX ;Pré-positionnement
39 L  Z+2 R0 F0.5 M99 ;Approche de la hauteur de départ et appel du cycle
40 ;
41 ;Tourner sur l'épaulement
42 CYCL DEF 811 ABSATZ LAENGS ~
   Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q493=+100  ;KONTURENDE DURCHMESSER ~
    Q494=-20   ;KONTURENDE Z ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.2  ;AUFMASS DURCHMESSER ~
    Q484=+0    ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q506=+0    ;KONTURGLAETTUNG
43 L  X+119  Y+0 R0 FMAX ;Pré-positionnement
44 L  Z+10 R0 FMAX ;Pré-positionnement
45 L  Z+2 R0 F0.5 M99 ;Approche de la hauteur de départ et appel du cycle
46 ;
47 ;Appel de l'outil de tournage axial de gorge
48 TOOL CALL "TURN_REC_AX_100-150"
49 ;
50 ;Appel du sous-programme Mode tournage
51 CALL LBL "TURN"
52 ;Appel du sous-programme Approche de la position de sécurité
53 CALL LBL "SAFE"
54 ;
55 ;Configurer le tournage
56 CYCL DEF 800 KOORD.-SYST.ANPASSEN ~
   Q497=+0    ;PRAEZESSIONSWINKEL ~
    Q498=+0    ;WERKZEUG UMKEHREN ~
    Q530=+0    ;ANGESTELLTE BEARB. ~
    Q531=+0    ;ANSTELLWINKEL ~
    Q532=+750  ;VORSCHUB ~
    Q533=+0    ;VORZUGSRICHTUNG ~
    Q535=+3    ;EXZENTERDREHEN ~
    Q536=+0    ;EXZENTR. OHNE STOPP
57 ;
58 ;Définir une vitesse de coupe constante
59 ;et une vitesse de rotation maximale
60 FUNCTION TURNDATA SPIN VCONST:ON VC:400 SMAX800
61 ;
62 ;Remettre l'axe de pivotement à zéro et
63 ;activer la broche de tournage
64 L  A+0 R0 FMAX M303
65 ;
66 ;Gorge axiale
67 CYCL DEF 852 STECHDR. ERW. AXIAL ~
   Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q491=+85   ;KONTURSTART DURCHMESSER ~
    Q492=+0    ;KONTURSTART Z ~
    Q493=+50   ;KONTURENDE DURCHMESSER ~
    Q494=-5    ;KONTURENDE Z ~
    Q495=+0    ;WINKEL FLANKE ~
    Q501=+1    ;TYP ANFANGSELEMENT ~
    Q502=+0.5  ;GROESSE ANFANGSELEMENT ~
    Q500=+0.5  ;RADIUS KONTURECKE ~
    Q496=+0    ;WINKEL ZWEITE FLANKE ~
    Q503=+1    ;TYP ENDELEMENT ~
    Q504=+0.5  ;GROESSE ENDELEMENT ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.4  ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q507=+0    ;BEARBEITUNGSRICHTUNG ~
    Q508=+0    ;VERSATZBREITE ~
    Q509=+0    ;TIEFENKORREKTUR
68 L  X+85  Y+0 R0 FMAX ;Pré-positionnement
69 L  Z+10 R0 FMAX ;Pré-positionnement
70 L  Z+2 R0 F0.5 M99 ;Approche de la hauteur de départ et appel du cycle
71 ;
72 ;Tournage gorge radiale
73 ;Appel de l'outil de tournage de gorge radiale
74 TOOL CALL "TURN_REC_RAD"
75 ;
76 ;Appel du sous-programme Mode tournage
77 CALL LBL "TURN"
78 ;Appel du sous-programme Approche de la position de sécurité
79 CALL LBL "SAFE"
80 ;
81 ;Configurer le tournage
82 CYCL DEF 800 KOORD.-SYST.ANPASSEN ~
   Q497=+0    ;PRAEZESSIONSWINKEL ~
    Q498=+0    ;WERKZEUG UMKEHREN ~
    Q530=+0    ;ANGESTELLTE BEARB. ~
    Q531=+0    ;ANSTELLWINKEL ~
    Q532=+750  ;VORSCHUB ~
    Q533=+0    ;VORZUGSRICHTUNG ~
    Q535=+3    ;EXZENTERDREHEN ~
    Q536=+0    ;EXZENTR. OHNE STOPP
83 ;
84 ;Définir une vitesse de coupe constante
85 ;et une vitesse de rotation maximale
86 FUNCTION TURNDATA SPIN VCONST:ON VC:400 SMAX800
87 ;
88 ;Remettre l'axe de pivotement à zéro
89 ;et activer la broche de tournage
90 L  A+0 R0 FMAX M303
91 ;
92 ;Faire tourner un contour
93 CYCL DEF 14.0 KONTUR
94 CYCL DEF 14.1 KONTURLABEL1
95 CYCL DEF 840 STECHDR. KONT. RAD. ~
   Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q488=+0.1  ;VORSCHUB EINTAUCHEN ~
    Q483=+0.4  ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q479=+0    ;SCHNITTBEGRENZUNG ~
    Q480=+0    ;GRENZWERT DURCHMESSER ~
    Q482=+0    ;GRENZWERT Z ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q507=+0    ;BEARBEITUNGSRICHTUNG ~
    Q508=+0    ;VERSATZBREITE ~
    Q509=+0    ;TIEFENKORREKTUR ~
    Q499=+0    ;KONTUR UMKEHREN
96 L  X+119  Y+0 R0 FMAX ;Pré-positionnement
97 L  Z+10 R0 FMAX ;Pré-positionnement
98 L  Z+2 R0 F0.5 M99 ;Approche de la hauteur de départ et appel du cycle
99 ;
100 ;Gorge radiale
101 CYCL DEF 841 STECHDR. EINFACH R. ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q493=+105  ;KONTURENDE DURCHMESSER ~
    Q494=-40   ;KONTURENDE Z ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.4  ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q507=+0    ;BEARBEITUNGSRICHTUNG ~
    Q508=+0    ;VERSATZBREITE ~
    Q509=+0    ;TIEFENKORREKTUR
102 L  X+119  Y+0 R0 FMAX ;Pré-positionnement
103 L  Z+10 R0 FMAX ;Pré-positionnement
104 L  Z-23 R0 F0.5 M99 ;Approche de la hauteur de départ et appel du cycle
105 ;
106 ;Fraisage perçage
107 ;Appel du sous-programme Mode fraisage
108 CALL LBL "MILL"
109 ;
110 ;Appel de la fraise deux tailles
111 TOOL CALL "MILL_D20_ROUGH" Z S3000 F700
112 ;
113 L  X+0  Y+0  Z+100 R0 FMAX M3 ;Pré-positionnement
114 ;
115 ;Fraisage du perçage
116 CYCL DEF 208 BOHRFRAESEN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q201=-60   ;TIEFE ~
    Q206=+500  ;VORSCHUB TIEFENZ. ~
    Q334=+2.5  ;ZUSTELL-TIEFE ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q335=+32   ;SOLL-DURCHMESSER ~
    Q342=+0    ;VORGEB. DURCHMESSER ~
    Q351=+1    ;FRAESART
117 M99 ;Appel de cycles
118 ;
119 ;Appel du sous-programme Approche de la position de sécurité
120 CALL LBL "SAFE"
121 ;
122 ;Ébauchage par tournage intérieur
123 ;Appel de l'outil de tournage pour ébauchage
124 TOOL CALL "TURN_ROUGH"
125 ;
126 ;Appel du sous-programme Mode tournage
127 CALL LBL "TURN"
128 ;Appel du sous-programme Approche de la position de sécurité
129 CALL LBL "SAFE"
130 ;
131 ;Configurer le tournage
132 CYCL DEF 800 KOORD.-SYST.ANPASSEN ~
    Q497=+0    ;PRAEZESSIONSWINKEL ~
    Q498=+1    ;WERKZEUG UMKEHREN ~
    Q530=+0    ;ANGESTELLTE BEARB. ~
    Q531=+0    ;ANSTELLWINKEL ~
    Q532=+750  ;VORSCHUB ~
    Q533=+0    ;VORZUGSRICHTUNG ~
    Q535=+3    ;EXZENTERDREHEN ~
    Q536=+0    ;EXZENTR. OHNE STOPP
133 ;
134 ;Définir une vitesse de coupe constante
135 ;et une vitesse de rotation maximale
136 FUNCTION TURNDATA SPIN VCONST:ON VC:400 SMAX800
137 ;
138 ;Mettre l'axe de pivotement à zéro et
139 ;activer la broche de tournage
140 ;(M304 car outil inversé)
141 L  A+0 R0 FMAX M304
142 ;
143 ;Tourner l'épaulement vers l'intérieur
144 CYCL DEF 821 ABSATZ PLAN ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q493=+84   ;KONTURENDE DURCHMESSER ~
    Q494=-5    ;KONTURENDE Z ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.4  ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q506=+0    ;KONTURGLAETTUNG
145 L  X+30  Y+0 R0 FMAX ;Pré-positionnement
146 L  Z+2 R0 FMAX M99 ;Approche de la position de départ et appel du cycle
147 ;
148 ;Tourner l'épaulement vers l'intérieur
149 CYCL DEF 822 ABSATZ PLAN ERW. ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q491=+32   ;KONTURSTART DURCHMESSER ~
    Q492=-5    ;KONTURSTART Z ~
    Q493=+75   ;KONTURENDE DURCHMESSER ~
    Q494=-40   ;KONTURENDE Z ~
    Q495=+0    ;WINKEL PLANFLAECHE ~
    Q501=+0    ;TYP ANFANGSELEMENT ~
    Q502=+1    ;GROESSE ANFANGSELEMENT ~
    Q500=+1    ;RADIUS KONTURECKE ~
    Q496=+0    ;WINKEL UMFANGSFLAECHE ~
    Q503=+2    ;TYP ENDELEMENT ~
    Q504=+1    ;GROESSE ENDELEMENT ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.4  ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q506=+0    ;KONTURGLAETTUNG
150 L  X+30  Y+0 R0 FMAX ;Pré-positionnement
151 L  Z-3 R0 FMAX M99 ;Approche de la position de départ et appel du cycle
152 L  Z+10 R0 FMAX ;Dégagement
153 ;
154 ;Appel du sous-programme Approche de la position de sécurité
155 CALL LBL "SAFE"
156 ;
157 ;Finition extérieure de tournage
158 ;Appel de l'outil de tournage pour finition
159 TOOL CALL "TURN_FINISH"
160 ;
161 ;Appel du sous-programme Mode tournage
162 CALL LBL "TURN"
163 ;
164 ;Activation de la mise en place de la pièce brute
165 ;Pièce brute définie dans le sous-programme Blank
166 FUNCTION TURNDATA BLANK LBL "Blank"
167 ;
168 ;Configurer le tournage
169 ;L'outil est activé car la gorge est en
170 ;cours de réalisation
171 CYCL DEF 800 KOORD.-SYST.ANPASSEN ~
    Q497=+90   ;PRAEZESSIONSWINKEL ~
    Q498=+0    ;WERKZEUG UMKEHREN ~
    Q530=+2    ;ANGESTELLTE BEARB. ~
    Q531=+30   ;ANSTELLWINKEL ~
    Q532=+750  ;VORSCHUB ~
    Q533=-1    ;VORZUGSRICHTUNG ~
    Q535=+3    ;EXZENTERDREHEN ~
    Q536=+0    ;EXZENTR. OHNE STOPP
172 ;
173 ;Définir une vitesse de coupe constante
174 ;et une vitesse de rotation maximale
175 FUNCTION TURNDATA SPIN VCONST:ON VC:500 S800
176 ;
177 M303
178 ;Finition du contour
179 CYCL DEF 14.0 KONTUR
180 CYCL DEF 14.1 KONTURLABEL3
181 CYCL DEF 810 DREHEN KONTUR LAENGS ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q499=+0    ;KONTUR UMKEHREN ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.1  ;AUFMASS DURCHMESSER ~
    Q484=+0.1  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q487=+1    ;EINTAUCHEN ~
    Q488=+0    ;VORSCHUB EINTAUCHEN ~
    Q479=+0    ;SCHNITTBEGRENZUNG ~
    Q480=+0    ;GRENZWERT DURCHMESSER ~
    Q482=+0    ;GRENZWERT Z ~
    Q506=+0    ;KONTURGLAETTUNG
182 M99 ;Appel de cycles
183 ;
184 ;Tournage Filetage
185 ;Appel de l'outil de filetage
186 TOOL CALL "TURN_THREAD"
187 ;
188 ;Appel du sous-programme Mode tournage
189 CALL LBL "TURN"
190 ;
191 ;Appel du sous-programme Approche de la position de sécurité
192 CALL LBL "SAFE"
193 ;
194 ;Configurer le tournage
195 CYCL DEF 800 KOORD.-SYST.ANPASSEN ~
    Q497=+0    ;PRAEZESSIONSWINKEL ~
    Q498=+0    ;WERKZEUG UMKEHREN ~
    Q530=+0    ;ANGESTELLTE BEARB. ~
    Q531=+0    ;ANSTELLWINKEL ~
    Q532=+750  ;VORSCHUB ~
    Q533=+0    ;VORZUGSRICHTUNG ~
    Q535=+3    ;EXZENTERDREHEN ~
    Q536=+0    ;EXZENTR. OHNE STOPP
196 ;
197 ;Définir une vitesse de coupe constante
198 ;et une vitesse de rotation maximale
199 FUNCTION TURNDATA SPIN VCONST:ON VC:300 SMAX800
200 ;
201 ;Remettre l'axe de pivotement à zéro
202 ;et activer la broche de tournage
203 L  A+0 R0 FMAX M304
204 ;
205 ;Filetage
206 CYCL DEF 831 GEWINDE LAENGS ~
    Q471=+0    ;GEWINDELAGE ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q491=+95   ;GEWINDEDURCHMESSER ~
    Q472=+1.5  ;GEWINDESTEIGUNG ~
    Q473=+0    ;GEWINDETIEFE ~
    Q492=+0    ;KONTURSTART Z ~
    Q494=-20   ;KONTURENDE Z ~
    Q474=+0    ;GEWINDEAUSLAUF ~
    Q463=+0.3  ;MAX. SCHNITTTIEFE ~
    Q467=+0    ;ZUSTELLWINKEL ~
    Q468=+1    ;ZUSTELLART ~
    Q470=+0    ;STARTWINKEL ~
    Q475=+1    ;GANGANZAHL ~
    Q476=+2    ;ANZAHL LEERSCHNITTE
207 L  X+98  Y+0 R0 FMAX ;Pré-positionnement
208 L  Z+2 R0 FMAX ;Aborder la position de départ
209 M99 ;Appel de cycles
210 ;
211 ;Tournage gorge radiale
212 ;Appel de l'outil de tournage de gorge radiale
213 TOOL CALL "TURN_REC_RAD"
214 ;
215 ;Appel du sous-programme Mode tournage
216 CALL LBL "TURN"
217 ;Appel du sous-programme Approche de la position de sécurité
218 CALL LBL "SAFE"
219 ;
220 ;Configurer le tournage
221 CYCL DEF 800 KOORD.-SYST.ANPASSEN ~
    Q497=+0    ;PRAEZESSIONSWINKEL ~
    Q498=+0    ;WERKZEUG UMKEHREN ~
    Q530=+0    ;ANGESTELLTE BEARB. ~
    Q531=+0    ;ANSTELLWINKEL ~
    Q532=+750  ;VORSCHUB ~
    Q533=+0    ;VORZUGSRICHTUNG ~
    Q535=+3    ;EXZENTERDREHEN ~
    Q536=+0    ;EXZENTR. OHNE STOPP
222 ;
223 ;Définir une vitesse de coupe constante
224 ;et une vitesse de rotation maximale
225 FUNCTION TURNDATA SPIN VCONST:ON VC:400 SMAX800
226 ;
227 ;Remettre l'axe de pivotement à zéro
228 ;et activer la broche de tournage
229 L  A+0 R0 FMAX M303
230 ;
231 ;Tournage gorge radiale
232 ;Faire tourner un contour
233 CYCL DEF 14.0 KONTUR
234 CYCL DEF 14.1 KONTURLABEL4
235 CYCL DEF 840 STECHDR. KONT. RAD. ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q488=+0.1  ;VORSCHUB EINTAUCHEN ~
    Q483=+0.4  ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q479=+0    ;SCHNITTBEGRENZUNG ~
    Q480=+0    ;GRENZWERT DURCHMESSER ~
    Q482=+0    ;GRENZWERT Z ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q507=+0    ;BEARBEITUNGSRICHTUNG ~
    Q508=+0    ;VERSATZBREITE ~
    Q509=+0    ;TIEFENKORREKTUR ~
    Q499=+0    ;KONTUR UMKEHREN
236 L  X+119  Y+0 R0 FMAX ;Pré-positionnement
237 L  Z+10 R0 FMAX ;Pré-positionnement
238 L  Z+2 R0 F0.5 M99 ;Approche de la position de départ et appel du cycle
239 ;
240 ;Appel du sous-programme Mode fraisage
241 CALL LBL "MILL"
242 ;Appel du sous-programme Approche de la position de sécurité
243 CALL LBL "SAFE"
244 ;Fin du programme
245 M30
246 ;
247 ;Sous-programme Mode Tournage
248 LBL "TURN"
249 M140 MB MAX ;Dégagement
250 M145 ;Annuler le calcul de la cinématique
251 FUNCTION MODE TURN ;Activer le mode Tournage
252 M144 ;Activer le calcul de la cinématique
253 M136 ;Basculer l'avance sur mm par tour
254 LBL 0
255 ;
256 ;Sous-programme mode Fraisage
257 LBL "MILL"
258 M140 MB MAX ;Dégagement
259 M145 ;Annuler le recalcul de la cinématique
260 FUNCTION MODE MILL ;Activer le mode Fraisage
261 M137 ;Régler l'avance sur mm par min
262 ;Appel de sous-programme Approche de la position de sécurité
263 CALL LBL "SAFE"
264 L  C+0  A+0 R0 FMAX ;Mettre à zéro les axes de pivotement
265 LBL 0
266 ;
267 ;Sous-programme Approche de la position de sécurité
268 LBL "SAFE"
269 L  X+400  Y+400 R0 FMAX M91 ;Position de sécurité !Selon la machine!
270 LBL 0
271 ;
272 ;Contour pour la mise en place de la pièce brute
273 LBL "Blank"
274 L  Z+0  X+0
275 L  Z+0  X+100
276 L  Z-20  X+100
277 L  Z-20  X+116.9997
278 L  Z-23  X+117
279 L  Z-23  X+105
280 L  Z-40  X+105
281 L  Z-40  X+116.9997
282 L  Z-43  X+117
283 L  Z-43  X+100
284 L  Z-56.9063  X+100
285 L  Z-56.9063  X+0
286 L  Z-60  X+117
287 L  Z-60  X+0
288 L  Z-80  X+117
289 L  Z-80  X+119.9997
290 L  Z-100  X+120
291 L  Z-100  X+0
292 L  Z+0
293 LBL 0
294 ;
295 ;Contour 1
296 LBL 1
297 L  X+117  Z-43 RL
298 L  X+100
299 L  Z-56.9063
300 L  X+117  Z-60
301 LBL 0
302 ;
303 ;Contour 3
304 LBL 3
305 L  X+90  Z+0
306 L  X+95
307 RND R2
308 L  Z-20
309 UDC THREAD PITCH1.5 R0.8 DEPTH0.8 BREADTH5 ;Dégagement
310 L  X+110
311 LBL 0
312 ;
313 ;Contour 4
314 LBL 4
315 L  X+105  Z-23
316 L  Z-27
317 GRV RADIAL CENTER-31.5 R1 DIAM89 BREADTH9 ANG_WIDTH28.072 RND1 FAR_RND1 ;Gorge
318 L  Z-40
319 LBL 0
320 END PGM 10005_FR MM