0 BEGIN PGM 1065_FR MM 
1 ;Programme permettant d'effectuer des pointages à
2 ;différentes positions, d'effectuer un perçage pilote
3 ;et de percer celui-ci plus en profondeur.
4 ;Les positions sont mémorisées dans un tableau, tout
5 ;comme d'autres paramètres de perçage.
6 ;
7 BLK FORM 0.1 Z X+0 Y+0 Z-100
8 BLK FORM 0.2  X+100  Y+100  Z+0
9 ;
10 ;Définition du tableau avec les paramètres de perçage
11 FN 26: TABOPEN 10651_fr.tab
12 ;
13 ;Appel d'outil : foret à centrer
14 TOOL CALL 203 Z S2000
15 ;
16 CYCL DEF 203 PERCAGE UNIVERSEL ~
   Q200=+2    ;DISTANCE D'APPROCHE ~
    Q201=-3    ;PROFONDEUR ~
    Q206=+150  ;AVANCE PLONGEE PROF. ~
    Q202=+5    ;PROFONDEUR DE PASSE ~
    Q210=+0    ;TEMPO. EN HAUT ~
    Q203=+0    ;COORD. SURFACE PIECE ~
    Q204=+50   ;SAUT DE BRIDE ~
    Q212=+0    ;VALEUR REDUCTION ~
    Q213=+0    ;NB BRISES COPEAUX ~
    Q205=+0    ;PROF. PASSE MIN. ~
    Q211=+0    ;TEMPO. AU FOND ~
    Q208=+30000 ;AVANCE RETRAIT ~
    Q256=+0.2  ;RETR. BRISE-COPEAUX
17 ;
18 ;Définition des lignes du tableau à utiliser
19 FN 0: Q51 =+0 ;LIGNE DE DEPART
20 FN 0: Q52 =+4 ;AUTRES LIGNES
21 ;
22 CALL LBL 12
23 ;
24 STOP
25 ;
26 ;Appel du foret pour le perçage pilote
27 TOOL CALL 227 Z S2000
28 ;
29 ;Définition des paramètres du cycle de perçage qui sont à modifier
30 FN 0: Q201 =-10 ;Nouvelle profondeur
31 ;
32 CALL LBL 12
33 ;
34 STOP
35 ;
36 ;Appel de l'outil pour le perçage profond
37 TOOL CALL 226 Z
38 ;
39 ;Définition des paramètres pour le perçage profond
40 FN 0: Q1 =+0 ;Arête supérieure
41 FN 0: Q2 =+0 ;Profondeur de pré-perçage
42 FN 0: Q3 =-10 ;Hauteur de débourrage
43 FN 0: Q4 =+1000 ;Avance d'approche
44 FN 0: Q5 =+200 ;Avance de perçage
45 FN 0: Q6 =+2000 ;Vitesse de rotation
46 FN 0: Q7 =+5 ;Passe
47 FN 0: Q8 =+0 ;Profondeur
48 FN 0: Q9 =+0.5 ;Temporisation
49 FN 0: Q10 =+1 ;Valeur de brise-copeaux
50 FN 0: Q11 =+2 ;Valeur d'approche 1 (valeur incrémentale)
51 FN 0: Q12 =+30 ;Valeur d'approche 2 (valeur incrémentale)
52 FN 0: Q13 =+5 ;Nombre de passes
53 ;
54 ;Définition du PGM 10652_fr.h comme cycle
55 CYCL DEF 12.0 PGM CALL
56 CYCL DEF 12.1 PGM 10652_fr.h
57 ;
58 CALL LBL 12
59 ;
60 ;Dégagement et fin de programme
61 L  X+0  Y+0  Z+100 FMAX M2
62 ;
63 ;Approche de la position
64 LBL 12
Q61 = Q51 ;Définition de la ligne du tableau correspondant à la première position
65 LBL 11
66 CALL LBL 10
67 FN 1: Q61 =+Q61 + +1 ;Recalcul de la ligne du tableau
68 CALL LBL 11 REPQ52
69 LBL 0
70 ;
71 ;Instructions de lecture, approche de la position et appel du cycle
72 LBL 10
73 FN 28: TABREAD Q41 =Q61 /"X"
74 FN 28: TABREAD Q42 =Q61 /"Y"
75 FN 28: TABREAD Q1 =Q61 /"Z"
76 FN 28: TABREAD Q8 =Q61 /"Depth"
77 FN 28: TABREAD Q45 =Q61 /"Distance"
78 FN 28: TABREAD Q46 =Q61 /"Feed_rate"
79 FN 28: TABREAD Q47 =Q61 /"Safe_height"
80 L  X+Q41  Y+Q42 R0 FMAX M13 M99
81 LBL 0
82 END PGM 1065_FR MM