0 BEGIN PGM 2125_FR MM 
1 ;Programme CN permettant de réaliser une poche avec le
2 ;contour extérieur d'une ellipse.
3 BLK FORM 0.1 Z X+0 Y+0 Z-20
4 BLK FORM 0.2  X+100  Y+100  Z+0
5 ;
6 ;Appel de la fraise deux tailles D10
7 TOOL CALL 5 Z S5000
8 ;
9 ;Données de coupe
Q50 = 20 ;PROFONDEUR FRAISAGE
Q51 = 3 ;PROFONDEUR DE PASSE
Q52 = 2 ;DISTANCE D'APPROCHE
Q53 = 150 ;AVANCE DE LA PASSE EN PROFONDEUR
Q54 = 500 ;AVANCE FRAISAGE
10 ;
11 ;Paramètres de l'ellipse
Q31 = 50 ;GRAND RAYON
Q32 = 25 ;PETIT RAYON
Q33 = 1 ;INCREMENT ANGULAIRE
Q38 = 50 ;CENTRE ELLIPSE X
Q39 = 50 ;CENTRE ELLIPSE Y
Q40 = 45 ;ROTATION
12 ;***Réinitialisation des paramètres
Q41 = 0 ;REINITIALISATION DE LA VALEUR ANGULAIRE
13 ;
14 ;===========================================
15 CYCL DEF 7.0 POINT ZERO
16 CYCL DEF 7.1  X+Q38
17 CYCL DEF 7.2  Y+Q39
18 CYCL DEF 10.0 ROTATION
19 CYCL DEF 10.1  ROT+Q40
20 CYCL DEF 14.0 CONTOUR
21 CYCL DEF 14.1 LABEL CONTOUR1
22 CYCL DEF 20 DONNEES DU CONTOUR ~
   Q1=-Q50  ;PROFONDEUR FRAISAGE ~
    Q2=+1    ;FACTEUR RECOUVREMENT ~
    Q3=+0    ;SUREPAIS. LATERALE ~
    Q4=+0    ;SUREP. DE PROFONDEUR ~
    Q5=+0    ;COORD. SURFACE PIECE ~
    Q6=+Q52  ;DISTANCE D'APPROCHE ~
    Q7=+50   ;HAUTEUR DE SECURITE ~
    Q8=+0    ;RAYON D'ARRONDI ~
    Q9=+1    ;SENS DE ROTATION
23 CYCL DEF 22 EVIDEMENT ~
   Q10=-Q51  ;PROFONDEUR DE PASSE ~
    Q11=+Q53  ;AVANCE PLONGEE PROF. ~
    Q12=+Q54  ;AVANCE EVIDEMENT ~
    Q18=+0    ;OUTIL PRE-EVIDEMENT ~
    Q19=+Q53  ;AVANCE PENDULAIRE ~
    Q208=+99999 ;AVANCE RETRAIT
24 M3 M99
25 CYCL DEF 7.0 POINT ZERO
26 CYCL DEF 7.1  X+0
27 CYCL DEF 7.2  Y+0
28 CYCL DEF 10.0 ROTATION
29 CYCL DEF 10.1  ROT+0
30 ;
31 ;Fin du programme
32 L  Z+50 R0 FMAX M30
33 ;
34 ;Sous-programme
35 ;***Description du contour
36 LBL 1
Q42 = COS Q41 * Q31 ;CALCUL NOUVELLE VALEUR X
Q43 = SIN Q41 * Q32 ;CALCUL NOUVELLE VALEUR Y
37 L  X+Q42  Y+Q43 RL
Q41 = Q41 + Q33 ;CALCUL NOUVELLE VALEUR ANGULAIRE
38 FN 12: IF +Q41 LT +360 GOTO LBL 1
39 LBL 0
40 END PGM 2125_FR MM