0 BEGIN PGM 2130_FR MM 
1 ;Programme CN permettant de réaliser une poche avec le
2 ;contour d'un profil polygonal P3G selon la norme
3 ;DIN 32711.
4 BLK FORM 0.1 Z X+0 Y+0 Z-25
5 BLK FORM 0.2  X+100  Y+100  Z+0
6 ;
7 ;Appel de la fraise deux tailles D20
8 TOOL CALL 13 Z S5000
9 ;
10 ;Données de coupe
Q50 = 20 ;PROFONDEUR FRAISAGE
Q51 = 3 ;PROFONDEUR DE PASSE
Q52 = 2 ;DISTANCE D'APPROCHE
Q53 = 150 ;AVANCE DE LA PASSE EN PROFONDEUR
Q54 = 500 ;AVANCE FRAISAGE
11 ;
12 ;Paramètres du polygone P3G
Q30 = 75 ;DIAMETRE DE MEME EPAISSEUR (D1)
Q31 = 3.15 ;EXCENTRICITE (E)
Q36 = 50 ;CENTRE POLYGONE AXE X
Q37 = 50 ;CENTRE POLYGONE AXE Y
Q38 = 0 ;ROTATION
13 ;Fin de la programmation des paramètres
14 ;===========================================
Q35 = 0 ;DEPART DE L'INCREMENT ANGULAIRE
15 CYCL DEF 7.0 POINT ZERO
16 CYCL DEF 7.1  X+Q36
17 CYCL DEF 7.2  Y+Q37
18 CYCL DEF 10.0 ROTATION
19 CYCL DEF 10.1  ROT+Q38
20 CYCL DEF 14.0 CONTOUR
21 CYCL DEF 14.1 LABEL CONTOUR1
22 CYCL DEF 20 DONNEES DU CONTOUR ~
   Q1=-Q50  ;PROFONDEUR FRAISAGE ~
    Q2=+1    ;FACTEUR RECOUVREMENT ~
    Q3=+0    ;SUREPAIS. LATERALE ~
    Q4=+0    ;SUREP. DE PROFONDEUR ~
    Q5=+0    ;COORD. SURFACE PIECE ~
    Q6=+Q52  ;DISTANCE D'APPROCHE ~
    Q7=+50   ;HAUTEUR DE SECURITE ~
    Q8=+0    ;RAYON D'ARRONDI ~
    Q9=+1    ;SENS DE ROTATION
23 CYCL DEF 22 EVIDEMENT ~
   Q10=-Q51  ;PROFONDEUR DE PASSE ~
    Q11=+Q53  ;AVANCE PLONGEE PROF. ~
    Q12=+Q54  ;AVANCE EVIDEMENT ~
    Q18=+0    ;OUTIL PRE-EVIDEMENT ~
    Q19=+0    ;AVANCE PENDULAIRE ~
    Q208=+99999 ;AVANCE RETRAIT
24 L  X+0  Y+0 R0 FMAX M3 M99
25 CYCL DEF 10.0 ROTATION
26 CYCL DEF 10.1  ROT+0
27 CYCL DEF 7.0 POINT ZERO
28 CYCL DEF 7.1  X+0
29 CYCL DEF 7.2  Y+0
30 ;
31 ;Fin du programme
32 L  Z+50 R0 FMAX M30
33 ;
34 ;Sous-programme
35 ;Calcul des points de contour
36 LBL 1
Q40 = ( ( Q30 / 2 ) - Q31 * COS ( 3 * Q35 ) ) * COS Q35 - 3 * Q31 * SIN ( 3 * Q35 ) * SIN Q35
Q41 = ( ( Q30 / 2 ) - Q31 * COS ( 3 * Q35 ) ) * SIN Q35 + 3 * Q31 * SIN ( 3 * Q35 ) * COS Q35
37 L  X+Q40  Y+Q41 RL
Q35 = Q35 + 0.5
38 FN 10: IF +Q35 NE +360.5 GOTO LBL 1
39 LBL 0
40 END PGM 2130_FR MM