0 BEGIN PGM 2145_FR MM 
1 ;Programme CN dans lequel un cycle SL est défini.
2 ;Particularité : il est possible de sélectionner
3 ;dans un paramètre Q le numéro du sous-programme
4 ;à utiliser comme contour. Pour cela, vous
5 ;définissez en début de programme un paramètre avec
6 ;le numéro du sousprogramme à utiliser
7 ;(11 ou 12 dans cet exemple). Dans le cycle 14
8 ;figure ainsi le numéro du sous-programme de l'îlot
9 ;et celui d'un autre sous-programme. Ce deuxième
10 ;sousprogramme est uniquement composé d'un CALL LBL
11 ;avec le paramètre Q défini au début, pour que le
12 ;programme CN sélectionné soit utilisé.
13 ;
14 BLK FORM 0.1 Z X+200 Y-50 Z-10
15 BLK FORM 0.2  X+300  Y+50  Z+30
16 ;
17 ;Appel d'outil
18 TOOL CALL 4 Z S8000
19 ;
20 L  Z+100 R0 F9999 M3 ;Dégagement
21 ;
22 FN 0: Q30 =+12 ;CHOIX DU CONTOUR DE POCHE
23 ;
24 ;Définition du label de contour
25 CYCL DEF 14.0 CONTOUR
26 CYCL DEF 14.1 LABEL CONTOUR10 /2
27 ;
28 ;Cycles d'usinage
29 CYCL DEF 20 DONNEES DU CONTOUR ~
   Q1=-34   ;PROFONDEUR FRAISAGE ~
    Q2=+1    ;FACTEUR RECOUVREMENT ~
    Q3=+0    ;SUREPAIS. LATERALE ~
    Q4=+0    ;SUREP. DE PROFONDEUR ~
    Q5=+30   ;COORD. SURFACE PIECE ~
    Q6=+2    ;DISTANCE D'APPROCHE ~
    Q7=+5    ;HAUTEUR DE SECURITE ~
    Q8=+0    ;RAYON D'ARRONDI ~
    Q9=+1    ;SENS DE ROTATION
30 CYCL DEF 22 EVIDEMENT ~
   Q10=-4    ;PROFONDEUR DE PASSE ~
    Q11=+300  ;AVANCE PLONGEE PROF. ~
    Q12=+1500 ;AVANCE EVIDEMENT ~
    Q18=+0    ;OUTIL PRE-EVIDEMENT ~
    Q19=+500  ;AVANCE PENDULAIRE ~
    Q208=+99999 ;AVANCE RETRAIT ~
    Q401=+70   ;FACTEUR D'AVANCE ~
    Q404=+0    ;STRAT. SEMI-FINITION
31 CYCL CALL M3
32 L  Z+100 R0 F99999 ;Dégagement
33 M30 ;Fin du programme
34 ;
35 ;Sous-programmes
36 ;
37 LBL 2 ;Contour îlot
38 L  X+200  Y+26 RL
39 L  X+300  Y+36
40 L  Y-36
41 L  X+200  Y-26
42 L  X+200  Y+26
43 LBL 0
44 ;
45 LBL 10 ;Sous-programme Choix de la poche
46 CALL LBL Q30
47 LBL 0
48 ;
49 LBL 11 ;Contour Poche 1
50 L  X+194  Y-56 RR
51 L  Y+46
52 L  X+306
53 L  Y-46
54 L  X+194
55 LBL 0
56 ;
57 LBL 12 ;Contour Poche 2
58 L  X+194  Y-56 RR
59 L  Y+56
60 L  X+306
61 L  Y-56
62 L  X+194
63 LBL 0
64 END PGM 2145_FR MM