0 BEGIN PGM 3120_FR MM 
1 ;Programme permettant de fraiser un contour, puis
2 ;de l'arrondir avec un rayon au niveau de l'arête
3 ;supérieure. Dans l'exemple, un contour est
4 ;programmé comme îlot. Une fois les paramètres
5 ;nécessaires définis, la CN évide le contour.
6 ;Puis, elle calcule les modifications du contour en
7 ;tenant compte de la profondeur concernée. La CN
8 ;utilise alors celleci comme surépaisseur latérale
9 ;dans le cycle, afin d'usiner le rayon avec des
10 ;lignes de niveau, en ligne à ligne.
11 ;
12 BLK FORM 0.1 Z X+0 Y+0 Z-20
13 BLK FORM 0.2  X+100  Y+100  Z+0
14 ;
15 ;Définition des paramètres
16 FN 0: Q31 =+15 ;TIEFE KONTUR
17 FN 0: Q32 =+5 ;PROFONDEUR DE PASSE FRAISAGE CONTOUR
18 FN 0: Q33 =+1200 ;AVANCE FRAISAGE CONTOUR
19 FN 0: Q34 =+300 ;AVANCE DE LA PASSE EN PROFONDEUR
20 FN 0: Q41 =+8 ;RAYON D'ARRONDI
21 FN 0: Q42 =+0.1 ;PROFONDEUR DE PASSE USINAGE RAYON
22 FN 0: Q48 =+3000 ;AVANCE FRAISAGE RAYON
23 ;Fin de la programmation des paramètres
24 ;
25 ;Appel de la fraise deux tailles
26 TOOL CALL 13 Z S1000
27 ;
28 ;Déplacement à la hauteur de sécurité
29 L  Z+100 R0 FMAX M3
30 ;
31 ;Fraise pour le contour
32 CYCL DEF 14.0 CONTOUR
33 CYCL DEF 14.1 LABEL CONTOUR1 /2
34 CYCL DEF 20 DONNEES DU CONTOUR ~
   Q1=-Q31  ;PROFONDEUR FRAISAGE ~
    Q2=+1    ;FACTEUR RECOUVREMENT ~
    Q3=+0    ;SUREPAIS. LATERALE ~
    Q4=+0    ;SUREP. DE PROFONDEUR ~
    Q5=+0    ;COORD. SURFACE PIECE ~
    Q6=+0    ;DISTANCE D'APPROCHE ~
    Q7=+0    ;HAUTEUR DE SECURITE ~
    Q8=+0    ;RAYON D'ARRONDI ~
    Q9=+1    ;SENS DE ROTATION
35 CYCL DEF 22 EVIDEMENT ~
   Q10=-Q32  ;PROFONDEUR DE PASSE ~
    Q11=+Q34  ;AVANCE PLONGEE PROF. ~
    Q12=+Q33  ;AVANCE EVIDEMENT ~
    Q18=+0    ;OUTIL PRE-EVIDEMENT ~
    Q19=+Q33  ;AVANCE PENDULAIRE
36 CYCL CALL M13
37 ;
38 ;Usinage ligne-à-ligne du rayon
39 FN 0: Q44 =+Q42
40 LBL 3
41 ;Calculs de la modification du contour à une nouvelle profondeur
Q43 = Q41 * Q41
Q45 = Q41 - Q42
42 FN 3: Q45 =+Q45 * +Q45
Q43 = Q43 - Q45
Q43 = SQRT Q43
43 FN 2: Q50 =+Q41 - +Q43
44 ;Fin des calculs
45 ;Définition du cycle
46 CYCL DEF 14.0 CONTOUR
47 CYCL DEF 14.1 LABEL CONTOUR1
48 CYCL DEF 25 TRACE DE CONTOUR ~
   Q1=-Q42  ;PROFONDEUR FRAISAGE ~
    Q3=-Q50  ;SUREPAIS. LATERALE ~
    Q5=+0    ;COORD. SURFACE PIECE ~
    Q7=+2    ;HAUTEUR DE SECURITE ~
    Q10=-Q42  ;PROFONDEUR DE PASSE ~
    Q11=+Q34  ;AVANCE PLONGEE PROF. ~
    Q12=+Q48  ;AVANCE EVIDEMENT ~
    Q15=+1    ;MODE FRAISAGE
49 CYCL CALL M13
50 ;
51 FN 1: Q42 =+Q42 + +Q44 ;Actualisation de la profondeur
52 ;Comparaison pour savoir si d'autres trajectoires sont
53 ;nécessaires
54 FN 12: IF +Q42 LT +Q41 GOTO LBL 3
55 FN 9: IF +Q42 EQU +Q41 GOTO LBL 3
56 ;
57 ;Dégagement et fin de programme
58 L  Z+100 R0 FMAX M30
59 ;
60 ;Sous-programmes de contours
61 LBL 1 ;PGM CONTOUR
62 L  X+5  Y+30 RL
63 CC  X+15  Y+30
64 C  X+6.645  Y+35.495 DR-
65 CT  X+55.505  Y+69.488
66 CT  X+58.995  Y+30.025
67 CT  X+19.732  Y+21.191
68 CT  X+5  Y+30
69 LBL 0
70 ;
71 LBL 2 ;PGM Cadre
72 L  X-30  Y-20 RR
73 L  Y+120
74 L  X+120
75 L  Y-20
76 L  X-30
77 LBL 0
78 END PGM 3120_FR MM