0 BEGIN PGM 3250_FR MM 
1 ;Programme CN permettant d'usiner un contour avec
2 ;le cycle 25 et de d'arrondir l'arête supérieure
3 ;avec un rayon.
4 ;La CN usine le rayon en ligne-à-ligne avec des
5 ;lignes de niveau. Pour calculer les lignes de
6 ;niveau, la CN lit le rayon 2 depuis le tableau
7 ;d'outils.
8 ;Il est ainsi possible d'effectuer l'usinage avec
9 ;une fraise deux tailles, une fraise boule ou une
10 ;fraise torique sans avoir à modifier quoi que ce
11 ;soit au programme CN.
12 ;
13 BLK FORM 0.1 Z X+0 Y+0 Z-20
14 BLK FORM 0.2  X+100  Y+100  Z+0
15 ;
16 ;Appel de l'outil pour le fraisage de contour
17 TOOL CALL "MILL_D24_ROUGH" Z S6000 F2000
18 ;
19 L  Z+100 R0 FMAX M3 ;Dégagement
20 ;
21 CYCL DEF 14.0 CONTOUR
22 CYCL DEF 14.1 LABEL CONTOUR10
23 CYCL DEF 270 DONNEES TRACE CONT. ~
   Q390=+2    ;MODE D'APPROCHE ~
    Q391=+1    ;CORRECTION DE RAYON ~
    Q392=+10   ;RAYON ~
    Q393=+90   ;ANGLE AU CENTRE ~
    Q394=+0    ;DISTANCE
24 CYCL DEF 25 TRACE DE CONTOUR ~
   Q1=-15   ;PROFONDEUR FRAISAGE ~
    Q3=+0    ;SUREPAIS. LATERALE ~
    Q5=+0    ;COORD. SURFACE PIECE ~
    Q7=+50   ;HAUTEUR DE SECURITE ~
    Q10=-5    ;PROFONDEUR DE PASSE ~
    Q11=+150  ;AVANCE PLONGEE PROF. ~
    Q12=+500  ;AVANCE EVIDEMENT ~
    Q15=+1    ;MODE FRAISAGE ~
    Q18=+0    ;OUTIL PRE-EVIDEMENT ~
    Q446=+0.01 ;MATERIAU RESTANT ~
    Q447=+10   ;ECART DE CONNEXION ~
    Q448=+2    ;EXTENS. TRAJECTOIRE
25 M99 ;Appel du cycle
26 ;
27 ;Appel de la fraise hémisphérique
28 TOOL CALL "TORUS_MILL_D16_3" Z S6000 F2000
29 ;
30 L  Z+100 R0 FMAX M3 ;Dégagement
31 ;
32 ;Programmation de l'arrondi
Q50 = 6 ;RAYON DE L'ARETE
Q51 = 3 ;PASSE EN DEGRES
33 CALL LBL "RADIUS" ;Appel du sous-programme de fraisage du rayon
34 ;
35 L  Z+100 R0 FMAX ;Dégagement
36 M30 ;Fin du programme
37 ;
38 ;Sous-programmes
39 LBL 10 ;Contour
40 L  X+10  Y+10
41 L  Y+90
42 CR  X+90  Y+90 R+100 DR+
43 L  Y+10
44 CR  X+10  Y+10 R+100 DR-
45 LBL 0
46 ;
47 ;Sous-programme du rayon
48 LBL "RADIUS"
49 CYCL DEF 14.0 CONTOUR
50 CYCL DEF 14.1 LABEL CONTOUR10
51 CYCL DEF 270 DONNEES TRACE CONT. ~
   Q390=+2    ;MODE D'APPROCHE ~
    Q391=+1    ;CORRECTION DE RAYON ~
    Q392=+0    ;RAYON ~
    Q393=+0    ;ANGLE AU CENTRE ~
    Q394=+0    ;DISTANCE
52 FN 18: SYSREAD Q65 = ID50 NR3 ;Lecture du R2 de l'outil actif
Q61 = 0 ;Angle de départ
53 LBL 1 ;Marque de saut
Q61 = Q61 + Q51 ;Nouveau calcul de l'angle
54 FN 11: IF +Q61 GT +90 GOTO LBL "END1" ;Vérification si l'angle actuel est supérieur ou inférieur à 90°
55 FN 9: IF +Q61 EQU +90 GOTO LBL "END1" ;Vérification si l'angle est égal à 90°
Q62 = ( Q50 - COS Q61 * Q50 ) + ( Q65 - COS Q61 * Q65 ) ;Calcul de la profondeur de fraisage d'une ligne de niveau
Q63 = ( Q50 - SIN Q61 * Q50 ) + ( Q65 - SIN Q61 * Q65 ) ;Calcul de la surépaisseur d'une ligne de niveau
56 CYCL DEF 25 TRACE DE CONTOUR ~
   Q1=-Q62  ;PROFONDEUR FRAISAGE ~
    Q3=-Q63  ;SUREPAIS. LATERALE ~
    Q5=+0    ;COORD. SURFACE PIECE ~
    Q7=+2    ;HAUTEUR DE SECURITE ~
    Q10=-Q62  ;PROFONDEUR DE PASSE ~
    Q11= AUTO ;AVANCE PLONGEE PROF. ~
    Q12= AUTO ;AVANCE EVIDEMENT ~
    Q15=+1    ;MODE FRAISAGE ~
    Q18=+0    ;OUTIL PRE-EVIDEMENT ~
    Q446=+0.01 ;MATERIAU RESTANT ~
    Q447=+10   ;ECART DE CONNEXION ~
    Q448=+2    ;EXTENS. TRAJECTOIRE
57 M99 ;Appel du cycle
58 FN 9: IF +0 EQU +0 GOTO LBL 1 ;Saut
59 ;
60 ;Sous-programme de la dernière ligne de niveau
61 LBL "END1"
Q61 = 90 ;Angle final
Q62 = ( Q50 - COS Q61 * Q50 ) + ( Q65 - COS Q61 * Q65 ) ;Profondeur de la dernière ligne de niveau
Q63 = ( Q50 - SIN Q61 * Q50 ) + ( Q65 - SIN Q61 * Q65 ) ;Surépaisseur de la dernière ligne de niveau
62 CYCL DEF 25 TRACE DE CONTOUR ~
   Q1=-Q62  ;PROFONDEUR FRAISAGE ~
    Q3=-Q63  ;SUREPAIS. LATERALE ~
    Q5=+0    ;COORD. SURFACE PIECE ~
    Q7=+2    ;HAUTEUR DE SECURITE ~
    Q10=-Q62  ;PROFONDEUR DE PASSE ~
    Q11= AUTO ;AVANCE PLONGEE PROF. ~
    Q12= AUTO ;AVANCE EVIDEMENT ~
    Q15=+1    ;MODE FRAISAGE ~
    Q18=+0    ;OUTIL PRE-EVIDEMENT ~
    Q446=+0.01 ;MATERIAU RESTANT ~
    Q447=+10   ;ECART DE CONNEXION ~
    Q448=+2    ;EXTENS. TRAJECTOIRE
63 M99 ;Appel du cycle
64 L  Z+20 R0 FMAX ;Dégagement
65 LBL 0
66 END PGM 3250_FR MM