0 BEGIN PGM 3255_FR MM 
1 ;Programme CN permettant d'usiner un contour avec
2 ;le cycle 25, puis d'usiner un chanfrein en
3 ;ligne-à-ligne sur son arête supérieure.
4 ;La CN usine le chanfrein en ligne-à-ligne. Pour
5 ;calculer les lignes de niveau, la CN lit le
6 ;rayon 2 depuis le tableau d'outils. Il est ainsi
7 ;possible d'effectuer l'usinage avec une fraise deux
8 ;tailles, une fraise boule ou une fraise torique sans
9 ;avoir à modifier quoi que ce soit au programme CN.
10 ;
11 BLK FORM 0.1 Z X+0 Y+0 Z-20
12 BLK FORM 0.2  X+100  Y+100  Z+0
13 ;
14 ;Appel de l'outil pour le fraisage de contour
15 TOOL CALL "MILL_D24_ROUGH" Z S6000 F2000
16 ;
17 L  Z+100 R0 FMAX M3 ;Dégagement
18 ;
19 CYCL DEF 14.0 CONTOUR
20 CYCL DEF 14.1 LABEL CONTOUR10
21 CYCL DEF 270 DONNEES TRACE CONT. ~
   Q390=+2    ;MODE D'APPROCHE ~
    Q391=+1    ;CORRECTION DE RAYON ~
    Q392=+10   ;RAYON ~
    Q393=+90   ;ANGLE AU CENTRE ~
    Q394=+0    ;DISTANCE
22 CYCL DEF 25 TRACE DE CONTOUR ~
   Q1=-15   ;PROFONDEUR FRAISAGE ~
    Q3=+0    ;SUREPAIS. LATERALE ~
    Q5=+0    ;COORD. SURFACE PIECE ~
    Q7=+50   ;HAUTEUR DE SECURITE ~
    Q10=-5    ;PROFONDEUR DE PASSE ~
    Q11=+150  ;AVANCE PLONGEE PROF. ~
    Q12=+500  ;AVANCE EVIDEMENT ~
    Q15=+1    ;MODE FRAISAGE ~
    Q18=+0    ;OUTIL PRE-EVIDEMENT ~
    Q446=+0.01 ;MATERIAU RESTANT ~
    Q447=+10   ;ECART DE CONNEXION ~
    Q448=+2    ;EXTENS. TRAJECTOIRE
23 M99 ;Appel du cycle
24 ;
25 ;Appel de l'outil de fraisage du chanfrein
26 TOOL CALL "BALL_MILL_D10" Z S6000 F2000
27 ;
28 L  Z+100 R0 FMAX M3
29 ;
30 ;Définition des paramètres du chanfrein
Q50 = 30 ;ANGLE DU CHANFREIN
Q51 = 0.2 ;DISTANCE ENTRE LES LIGNES DE NIVEAU
Q52 = 2.5 ;LONGUEUR DU CHANFREIN EN HAUT
31 CALL LBL "FASE" ;Appel du sous-programme pour le fraisage du chanfrein
32 ;
33 L  Z+100 R0 FMAX ;Dégagement
34 M30 ;Fin du programme
35 ;
36 ;Sous-programmes
37 LBL 10 ;Contour
38 L  X+10  Y+10
39 L  Y+90
40 CR  X+90  Y+90 R+100 DR+
41 L  Y+10
42 CR  X+10  Y+10 R+100 DR-
43 LBL 0
44 ;
45 ;Sous-programme du chanfrein
46 LBL "FASE"
47 CYCL DEF 14.0 CONTOUR
48 CYCL DEF 14.1 LABEL CONTOUR10
Q49 = Q108 + 2 ;Rayon d'approche en douceur
49 CYCL DEF 270 DONNEES TRACE CONT. ~
   Q390=+2    ;MODE D'APPROCHE ~
    Q391=+1    ;CORRECTION DE RAYON ~
    Q392=+Q49  ;RAYON ~
    Q393=+90   ;ANGLE AU CENTRE ~
    Q394=+0    ;DISTANCE
50 FN 18: SYSREAD Q65 = ID50 NR3 ;Lecture du R2 de l'outil actif
Q61 = 0 ;Départ en Z
51 LBL 1
Q60 = Q52 / ( TAN Q50 ) ;Profondeur globale en Z
Q61 = Q61 + Q51 ;Calcul de la coordonnée Z de la nouvelle ligne de niveau
52 FN 11: IF +Q61 GT +Q60 GOTO LBL "END1" ;Vérification pour savoir si la nouvelle profondeur est supérieure ou inférieure à la profondeur globale
53 FN 9: IF +Q61 EQU +Q60 GOTO LBL "END1" ;Vérification pour savoir si la nouvelle profondeur est égale à la profondeur globale
Q62 = Q61 + ( Q65 - SIN Q50 * Q65 ) ;Calcul de la nouvelle coordonnée Z en tenant compte du rayon de l'outil R2 
Q63 = ( Q52 - TAN Q50 * Q61 ) + ( Q65 - COS Q50 * Q65 ) ;Calcul de la surépaisseur d'une ligne de niveau
54 CYCL DEF 25 TRACE DE CONTOUR ~
   Q1=-Q62  ;PROFONDEUR FRAISAGE ~
    Q3=-Q63  ;SUREPAIS. LATERALE ~
    Q5=+0    ;COORD. SURFACE PIECE ~
    Q7=+2    ;HAUTEUR DE SECURITE ~
    Q10=-Q62  ;PROFONDEUR DE PASSE ~
    Q11= AUTO ;AVANCE PLONGEE PROF. ~
    Q12= AUTO ;AVANCE EVIDEMENT ~
    Q15=+1    ;MODE FRAISAGE ~
    Q18=+0    ;OUTIL PRE-EVIDEMENT ~
    Q446=+0.01 ;MATERIAU RESTANT ~
    Q447=+10   ;ECART DE CONNEXION ~
    Q448=+2    ;EXTENS. TRAJECTOIRE
55 M99 ;Appel du cycle
56 FN 9: IF +0 EQU +0 GOTO LBL 1 ;Saut
57 ;
58 ;Sous-programme de la dernière ligne de niveau
59 LBL "END1"
Q61 = Q60 ;Profondeur finale
Q62 = Q61 + ( Q65 - SIN Q50 * Q65 ) ;Calcul de la coordonnée Z en tenant compte du rayon de l'outil R2
Q63 = ( Q52 - TAN Q50 * Q61 ) + ( Q65 - COS Q50 * Q65 ) ;Calcul de la surépaisseur d'une ligne de niveau
60 CYCL DEF 25 TRACE DE CONTOUR ~
   Q1=-Q62  ;PROFONDEUR FRAISAGE ~
    Q3=-Q63  ;SUREPAIS. LATERALE ~
    Q5=+0    ;COORD. SURFACE PIECE ~
    Q7=+2    ;HAUTEUR DE SECURITE ~
    Q10=-Q62  ;PROFONDEUR DE PASSE ~
    Q11= AUTO ;AVANCE PLONGEE PROF. ~
    Q12= AUTO ;AVANCE EVIDEMENT ~
    Q15=+1    ;MODE FRAISAGE ~
    Q18=+0    ;OUTIL PRE-EVIDEMENT ~
    Q446=+0.01 ;MATERIAU RESTANT ~
    Q447=+10   ;ECART DE CONNEXION ~
    Q448=+2    ;EXTENS. TRAJECTOIRE
61 M99 ;Appel du cycle
62 L  Z+20 R0 FMAX ;Dégagement
63 LBL 0
64 END PGM 3255_FR MM