0  BEGIN PGM 4040_FR MM 
1  BLK FORM 0.1 Z X-100 Y-100 Z-100
2  BLK FORM 0.2  X+100  Y+100  Z+0
3  ;Fraisage du tenon circulaire
4  ;Appel de l'outil
5  TOOL CALL 10 Z S3000 F800
6  L  X+0  Y+0  Z+100 R0 FMAX M3
7  CYCL DEF 257 TENON CIRCULAIRE ~
    Q223=+200  ;DIA. PIECE FINIE ~
    Q222=+283  ;DIAM. PIECE BRUTE ~
    Q368=+0    ;SUREPAIS. LATERALE ~
    Q207= AUTO ;AVANCE FRAISAGE ~
    Q351=+1    ;MODE FRAISAGE ~
    Q201=-80   ;PROFONDEUR ~
    Q202=+5    ;PROFONDEUR DE PASSE ~
    Q206= AUTO ;AVANCE PLONGEE PROF. ~
    Q200=+2    ;DISTANCE D'APPROCHE ~
    Q203=+0    ;COORD. SURFACE PIECE ~
    Q204=+50   ;SAUT DE BRIDE ~
    Q370=+1    ;FACTEUR RECOUVREMENT
8  M99
9  L  Z+100 R0 FMAX M5
10 ;Fraisage des rainures sur le pourtour cylindrique
11 ;Appel de l'outil
12 TOOL CALL 2 Z S5000 F500
13 ;Déplacement à une position de sécurité pour l'inclinaison de l'axe A
14 L  X+0  Y+0 R0 FMAX M3
15 M140 MB MAX F5000
16 ;Inclinaison de l'axe A
17 PLANE AXIAL  A-90 TURN FMAX
18 CALL LBL "MACHINING"
19 LBL "Takt"
20 ;Déplacement incrémental sur l'axe C
21 PLANE AXIAL IC+10 TURN FMAX
22 CALL LBL "MACHINING"
23 ;Répétition de la fréquence
24 CALL LBL "Takt" REP34
25 M140 MB MAX F5000
26 PLANE RESET TURN FMAX
27 M30 ;Fin du programme
28 ;Sous-programme
29 LBL "MACHINING"
30 ;Cycle d'usinage
31 ;Important : coordonnées de la surface = rayon du cylindre !
32 CYCL DEF 253 RAINURAGE ~
    Q215=+0    ;OPERATIONS D'USINAGE ~
    Q218=+20   ;LONGUEUR RAINURE ~
    Q219=+5    ;LARGEUR RAINURE ~
    Q368=+0    ;SUREPAIS. LATERALE ~
    Q374=+100  ;POSITION ANGULAIRE ~
    Q367=+0    ;POSITION RAINURE ~
    Q207=+500  ;AVANCE FRAISAGE ~
    Q351=+1    ;MODE FRAISAGE ~
    Q201=-5    ;PROFONDEUR ~
    Q202=+5    ;PROFONDEUR DE PASSE ~
    Q369=+0    ;SUREP. DE PROFONDEUR ~
    Q206=+150  ;AVANCE PLONGEE PROF. ~
    Q338=+0    ;PASSE DE FINITION ~
    Q200=+2    ;DISTANCE D'APPROCHE ~
    Q203=+100  ;COORD. SURFACE PIECE ~
    Q204=+50   ;SAUT DE BRIDE ~
    Q366=+0    ;PLONGEE ~
    Q385=+500  ;AVANCE DE FINITION
33 ;Position avec appel de cycle
34 L  X+0  Y+25 R0 FMAX M99
35 LBL 0
36 END PGM 4040_FR MM