0  BEGIN PGM 4225_FR MM 
1  ;Programme permettant d'effectuer plusieurs
2  ;usinages en ligne droite, avec un outil
3  ;incliné.
4  ;Dans cet exemple, les poches sont d'abord
5  ;fraisées avec une fraise en vue d'obtenir
6  ;une surface. Dans un deuxième temps, les
7  ;trous sont percés perpendiculairement à la
8  ;surface de base.
9  ;Il vous faut d'abord définir tous les
10 ;paramètres nécessaires. Les données d'outil,
11 ;et éventuellement les cycles, doivent
12 ;eux aussi être adaptés.
13 ;!IMPORTANT! Le programme est créé pour des
14 ;machines qui ont été configurées en prévision
15 ;d'une inclinaison avec des angles dans
16 ;l'espace. Si votre machine travaille uniquement
17 ;avec des angles dans l'espace, il vous faudra
18 ;également modifier les valeurs paramétrées dans
19 ;le cycle 19. Vous devrez aussi effectuer un
20 ;déplacement à une position de sécurité
21 ;dépendante de la machine avant d'incliner le
22 ;plan d'usinage, pour éviter tout risque de
23 ;collision au moment de déplacer les axes
24 ;rotatifs.
25 ;
26 BLK FORM 0.1 Z X+0 Y+0 Z-30
27 BLK FORM 0.2  X+100  Y+100  Z+0
28 ;
29 ;Définition des paramètres
30 ;Position et orientation des trous
31 FN 0: Q10 =+15 ;COORDONNEE DU 1ER TROU EN X
32 FN 0: Q11 =+15 ;COORDONNE DU 1ER TROU EN Y
33 FN 0: Q12 =+10 ;DISTANCE ENTRE LES TROUS SUR
34 ;              ;L'AXE X
35 FN 0: Q13 =+10 ;DISTANCE ENTRE LES TROUS SUR
36 ;              ;L'AXE Y
37 FN 0: Q14 =+8 ;NOMBRE DE TROUS
38 FN 0: Q15 =+30 ;ANGLE DANS L'ESPACE A POUR L'USINAGE
39 FN 0: Q16 =+0 ;ANGLE DANS L'ESPACE B POUR L'USINAGE
40 FN 0: Q17 =-150 ;ANGLE DANS L'ESPACE C POUR L'USINAGE
41 ;Paramètres de fraisage de la poche
42 FN 0: Q2 =+3 ;PROFONDEUR DE LA POCHE
43 FN 0: Q3 =+8 ;DIAMETRE DE LA POCHE
44 FN 0: Q18 =+400 ;AVANCE POUR LE FRAISAGE DE LA POCHE
45 ;Paramètres de perçage
46 FN 0: Q4 =+20 ;PROFONDEUR DE PERCAGE
47 FN 0: Q19 =+500 ;AVANCE DE PERCAGE
48 ;Fin de la programmation des paramètres
49 ;
50 ;Calculs
51 FN 2: Q1 =+Q14 - +2 ;Nombre de répétitions
52 ;Fin des calculs
53 ;
54 M3
55 ;Appel de la fraise deux tailles pour le pointage
56 TOOL CALL 2 Z S2000 F300
57 ;Appel du sous-programme de réinitialisation
58 CALL LBL 10
59 ;Cycle permettant d'avoir une surface plane, pour le pointage
60 CYCL DEF 252 POCHE CIRCULAIRE ~
    Q215=+0    ;OPERATIONS D'USINAGE ~
    Q223=+Q3   ;DIAMETRE DU CERCLE ~
    Q368=+0    ;SUREPAIS. LATERALE ~
    Q207=+Q18  ;AVANCE FRAISAGE ~
    Q351=+1    ;MODE FRAISAGE ~
    Q201=-Q2   ;PROFONDEUR ~
    Q202=+5    ;PROFONDEUR DE PASSE ~
    Q369=+0    ;SUREP. DE PROFONDEUR ~
    Q206=+Q18  ;AVANCE PLONGEE PROF. ~
    Q338=+0    ;PASSE DE FINITION ~
    Q200=+2    ;DISTANCE D'APPROCHE ~
    Q203=+0    ;COORD. SURFACE PIECE ~
    Q204=+50   ;SAUT DE BRIDE ~
    Q370=+1    ;FACTEUR RECOUVREMENT ~
    Q366=+1    ;PLONGEE ~
    Q385=+500  ;AVANCE DE FINITION
61 ;Appel du sous-programme pour le positionnement et
62 ;l'usinage
63 CALL LBL 3
64 ;Dégagement de l'outil
65 L  Z+50 F2222
66 ;
67 ;Appel d'outil : foret
68 TOOL CALL 227 Z S1000 F300
69 ;Définition du cycle de perçage
70 CYCL DEF 200 PERCAGE ~
    Q200=+5    ;DISTANCE D'APPROCHE ~
    Q201=-Q4   ;PROFONDEUR ~
    Q206=+Q19  ;AVANCE PLONGEE PROF. ~
    Q202=+5    ;PROFONDEUR DE PASSE ~
    Q210=+0    ;TEMPO. EN HAUT ~
    Q203=+0    ;COORD. SURFACE PIECE ~
    Q204=+50   ;SAUT DE BRIDE ~
    Q211=+0    ;TEMPO. AU FOND ~
    Q395=+0    ;REFERENCE PROFONDEUR
71 ;Appel du sous-programme pour le positionnement et
72 ;l'usinage
73 CALL LBL 3
74 ;Dégagement et fin de programme
75 L  Z+50 F2222 M30
76 ;
77 ;Sous-programme pour le positionnement et l'usinage
78 LBL 3
79 ;Décalage du point zéro au premier usinage
80 CYCL DEF 7.0 POINT ZERO
81 CYCL DEF 7.1  Y+Q10
82 CYCL DEF 7.2  X+Q11
83 ;Inclinaison du plan d'usinage
84 CYCL DEF 19.0 PLAN D'USINAGE
85 CYCL DEF 19.1  A+Q15  B+Q16  C+Q17
86 ;Approche de la position de sécurité
87 M140 MB MAX F9999
88 ;Positionnement des axes rotatifs
89 L  A+Q120  B+Q121  C+Q122 R0 FMAX
90 ;Approche de la première position d'usinage
91 L  X+0  Y+0  Z+50 R0 FMAX M3
92 ;Appel de cycle
93 M99
94 ;Répétition de la partie de programme pour d'autres
95 ;opérations d'usinage
96 LBL 2
97 ;Appel du sous-programme pour d'autres opérations
98 ;d'usinage
99 CALL LBL 1
100 ;Appel des répétitions
101 CALL LBL 2 REPQ1
102 ;Dégagement de l'outil
103 M140 MB MAX F9999
104 ;Appel du sous-programme de réinitialisation
105 CALL LBL 10
106 ;Réinitialisation des axes rotatifs
107 L  A+Q120  B+Q121  C+Q122 R0 FMAX
108 ;Réinitialisation du décalage de point zéro
109 CYCL DEF 7.0 POINT ZERO
110 CYCL DEF 7.1  Y+0
111 CYCL DEF 7.2  X+0
112 LBL 0
113 ;
114 ;Sous-programme pour d'autres opérations d'usinage
115 LBL 1
116 ;Appel du sous-programme de réinitialisation
117 CALL LBL 10
118 ;Décalage du point zéro à la position suivante, en
119 ;incrémental
120 CYCL DEF 7.0 POINT ZERO
121 CYCL DEF 7.1 IX+Q12
122 CYCL DEF 7.2 IY+Q13
123 ;Inclinaison du plan d'usinage
124 CYCL DEF 19.0 PLAN D'USINAGE
125 CYCL DEF 19.1  A+Q15  B+Q16  C+Q17
126 ;Approche de la position d'usinage
127 L  X+0  Y+0  Z+50 R0 FMAX
128 ;Appel de cycles
129 M99
130 ;Appel du sous-programme de réinitialisation
131 CALL LBL 10
132 LBL 0
133 ;
134 ;Sous-programme de réinitialisation
135 LBL 10
136 ;Réinitialisation de l'inclinaison du plan d'usinage
137 CYCL DEF 19.0 PLAN D'USINAGE
138 CYCL DEF 19.1  A+0  B+0  C+0
139 ;Désélection de l'inclinaison du plan d'usinage
140 CYCL DEF 19.0 PLAN D'USINAGE
141 CYCL DEF 19.1
142 ;Réinitialisation du facteur d'échelle
143 CYCL DEF 11.0 FACTEUR ECHELLE
144 CYCL DEF 11.1 SCL 1
145 ;Réinitialisation de la rotation
146 CYCL DEF 10.0 ROTATION
147 CYCL DEF 10.1  ROT+0
148 LBL 0
149 END PGM 4225_FR MM