0 BEGIN PGM 42301_DE MM 
1 ;Programme CN pour le calcul et l'usinage de la
2 ;vis sans fin.
3 ;En outre, le contour dans le plan X/Y est
4 ;programmé dans la partie de programme « SUBLOOP ».
5 ;Dans ce cas, il s'agit d'un contour composé de
6 ;trois sections identiques, qui a été programmé
7 ;une fois, puis répété deux fois pour une rotation
8 ;de 120 degrés.
9 ;Pour pouvoir réaliser les contre-dépouilles sur la
10 ;pièce, il est nécessaire de régler l'outil.
11 ;Pour ce faire, il faut utiliser la fonction TCPM,
12 ;le système de coordonnées, quant à lui, reste
13 ;inchangé. Mais lors du déplacement des axes rotatifs,
14 ;la CN prend en compte la cinématique et exécute le
15 ;TCP, dans ce cas le centre de la fraise boule, sur
16 ;la trajectoire programmée.
17 ;Les mouvements de compensation de l'axe C, programmés
18 ;pour les trajectoires circulaires du contour dans ce
19 ;programme, sont sélectionnés de manière à ce qu'aucune
20 ;violation de contour ne se produise.
21 ;
22 ;Début de programme
Q10 = Q9 ;Profondeur actuelle
Q12 = Q2 / Q1 ;Rotation par millimètre de profondeur
Q20 = 5 + Q108 + Q7 ;Premier rayon avec rayon de l'outil et surépaisseur inclus
Q30 = Q6 - ( ( Q6 - ( 25 + Q20 ) ) / 2 ) ;Centre de cercle pour une approche souple
23 PLANE RESET STAY ;Réinitialisation de l'inclinaison
24 L  Z+Q5 R0 FMAX M3 ;Approche de la hauteur de sécurité
25 FUNCTION TCPM F TCP AXIS SPAT PATHCTRL AXIS ;Activation de la fonction TCPM
26 CC  X+0  Y+0 ;Centre de cercle pour le pré-positionnement
27 LP  PR+Q6  PA+0 R0 FMAX ;Pré-positionnement
28 L  B+Q4  A+0  C+0 R0 FMAX ;Approche de l'angle d'inclinaison de l'axe B
29 ;
30 ;Marque de saut pour la répétition
31 LBL "MAINLOOP"
Q11 = Q10 * Q12 ;Calculer la rotation actuelle
32 ;
33 ;Rotation du système de coordonnées
34 CYCL DEF 10.0 DREHUNG
35 CYCL DEF 10.1  ROT+Q11
36 ;
37 L  C+Q11 R0 FMAX ;Mouvement de compensation de l'axe C
38 L  Z+Q10 R0 FMAX ;Approche des nouvelles coordonnées Z
39 CC  X+0  Y+0 ;Point central de pré-positionnement
40 LP  PR+Q6  PA+0 R0 FMAX ;Pré-positionner sur un rayon sécurisé
41 CC  X+Q30  Y+0 ;Centre du cercle pour le mouvement d'approche
42 CP  PA+180 DR- F AUTO ;Déplacement d'approche
43 CC  X+25  Y+0 ;Centre de cercle Rayon 5
44 ;
45 ;Répétition de partie de programme
46 ;dans laquelle le contour est décrit
47 LBL "SUBLOOP"
48 CP  PA+123.5 IC+33.5 DR+
49 CC  X+15.82  Y+13.86
50 CP IPA-102.6 IC+29.3 DR-
51 CC  X-23.05  Y-1.02
52 CP IPA+44.1 IC+48.8 DR+
53 CYCL DEF 10.0 DREHUNG
54 CYCL DEF 10.1 IROT+120
55 CC  X+25  Y+0
56 CP  PA+0 IC+8.4 DR+
57 CALL LBL "SUBLOOP" REP2
58 ;
59 CC  X+Q30  Y+0 ;Centre de cercle pour mouvement d'éloignement
60 CP  PA+0 DR- F AUTO ;Déplacement à la position de sécurité
61 L  Z+Q5 R0 FMAX ;Déplacement à la hauteur de sécurité
62 LBL 0
63 ;
Q10 = Q10 + Q3 ;Calcul de la nouvelle coordonnée Z
64 FN 11: IF +Q10 GT +Q1 GOTO LBL "MAINLOOP" ;Comparaison pour vérifier si la profondeur est atteinte et, si nécessaire, saut
65 FN 0: Q10 =+Q1 ;Les coordonnées Y sont égales à la profondeur
66 ;Saut vers le fraisage de contour
67 CALL LBL "MAINLOOP"
68 L  B+0  C+0  A+0 R0 FMAX M5 ;Réinitialisation de l'inclinaison de tous les axes rotatifs
69 FUNCTION RESET TCPM ;Réinitialisation de la fonction TCPM
70 ;Fin du programme
71 END PGM 42301_DE MM