0 BEGIN PGM 4240_fr MM 
1 ;Programme CN permettant d'usiner quatre
2 ;pièces avec une pyramide de serrage.
3 ;La commande fraise un chanfrein de 5*45
4 ;degrés sur chacune des pièces de
5 ;60*60*60mm. L'usinage est réalisé avec
6 ;une fraise en bout inclinée.
7 ;
8 ;Les pièces sont serrées sur une
9 ;pyramide, à un angle de 45 degrés.
10 ;
11 ;Les pièces sont positionnées comme suit :
12 ;Pièce 1 -> PRESET 6 --> Devant
13 ;Pièce 2 -> PRESET 7 --> Droite
14 ;Pièce 3 -> PRESET 8 --> Derrière
15 ;Pièce 4 -> PRESET 9 --> Gauche
16 ;
17 ;L'usinage de la pièce est programmé dans
18 ;le sous-programme "MACHINING".
19 ;La commande exécute ce sous-programme
20 ;à chaque preset, avec un angle
21 ;d'orientation différent.
22 ;Il est important que les angles 
23 ;d'alignement de la pyramide de serrage
24 ;soient respectivement configurés aux
25 ;paramètres QR170, QR171 et QR172.
26 ;Dans le sous-programme "MACHINING",
27 ;c'est d'abord l'outil qui est défini.
28 ;La commande appelle ensuite un
29 ;LBL "TILT..." pour chaque surface à
30 ;fraiser, puis le LBL "MILL".
31 ;Dans les sous-programmes "TILT...",
32 ;le décalage de point zéro et
33 ;l'inclinaison du plan d'usinage pour
34 ;l'usinage en cours sont définis, par
35 ;rapport au système de coordonnées de
36 ;la pièce.
37 ;La commande appelle ensuite le
38 ;LBL "TILT_NEW". 
39 ;Dans ce sous-programme, la commande se
40 ;base sur l'angle d'alignement de la
41 ;position de serrage, sur le décalage
42 ;de point zéro et sur l'inclinaison du
43 ;plan d'usinage pour calculer l'angle
44 ;dans l'espace qui en résulte, ainsi
45 ;que le décalage de point zéro, et
46 ;active ces derniers. Il s'ensuit alors
47 ;l'usinage programmé dans le LBL "MILL".
48 ;
49 * -Définition du côté 1 DEVANT
50 CYCL DEF 247 INIT. PT DE REF. ~
   Q339=+6    ;NUMERO POINT DE REF.
51 ;SPA aligné = QR170
QR170 = 45
52 ;SPB aligné = QR171
QR171 = 0
53 ;SPC aligné = QR172
QR172 = 0
54 CALL LBL "MACHINING"
55 ;
56 * -Définition du côté 2 DROITE
57 CYCL DEF 247 INIT. PT DE REF. ~
   Q339=+7    ;NUMERO POINT DE REF.
58 ;SPA aligné = QR170
QR170 = 45
59 ;SPB aligné = QR171
QR171 = 0
60 ;SPC aligné = QR172
QR172 = 90
61 CALL LBL "MACHINING"
62 ;
63 * -Définition du côté 3 DERRIERE
64 CYCL DEF 247 INIT. PT DE REF. ~
   Q339=+8    ;NUMERO POINT DE REF.
65 ;SPA aligné = QR170
QR170 = 45
66 ;SPB aligné = QR171
QR171 = 0
67 ;SPC aligné = QR172
QR172 = 180
68 CALL LBL "MACHINING"
69 ;
70 * -Définition du côté 4 GAUCHE
71 CYCL DEF 247 INIT. PT DE REF. ~
   Q339=+9    ;NUMERO POINT DE REF.
72 ;SPA aligné = QR170
QR170 = 45
73 ;SPB aligné = QR171
QR171 = 0
74 ;SPC aligné = QR172
QR172 = 270
75 CALL LBL "MACHINING"
76 ;
77 ;Réinitialiser toutes les conversions
78 ;de coordonnées
79 CALL LBL "RESET"
80 ;
81 ;Fin du programme
82 M30
83 ;
84 ;Sous-programmes
85 * -USINAGE
86 LBL "MACHINING"
87 * - Fraisage de surface 45
88 TOOL CALL "D16" Z S9000 F2000
89 CALL LBL "SAFE"
90 CALL LBL "TILT1"
91 CALL LBL "MILL"
92 CALL LBL "TILT2"
93 CALL LBL "MILL"
94 CALL LBL "TILT3"
95 CALL LBL "MILL"
96 CALL LBL "TILT4"
97 CALL LBL "MILL"
98 LBL 0
99 ;
100 * -  Fraisage
101 LBL "MILL"
102 L  X-20  Y+5  Z+50 R0 FMAX
103 L  Z+5 R0 FMAX
104 L  Z+0 R0 F2000
105 APPR LT  X+0  Y-1 LEN10 RL F AUTO
106 L  X+60
107 DEP LT LEN10
108 L  Z+50 R0 FMAX
109 LBL 0
110 ;
111 * - Inclinaison à 0 degrés
112 LBL "TILT0"
113 PLANE RESET STAY
114 CYCL DEF 7.0 POINT ZERO
115 CYCL DEF 7.1  X+0
116 CYCL DEF 7.2  Y+0
117 CYCL DEF 7.3  Z+0
118 CALL LBL "SAFE"
119 PLANE SPATIAL SPA+0 SPB+0 SPC+0 STAY SEQ-
120 ;Conversion sur le plan
121 CALL LBL "TILT_NEW"
122 LBL 0
123 ;
124 * - Inclinaison 1
125 LBL "TILT1"
126 PLANE RESET STAY
127 CYCL DEF 7.0 POINT ZERO
128 CYCL DEF 7.1  X-30
129 CYCL DEF 7.2  Y-30
130 CYCL DEF 7.3  Z-5
131 CALL LBL "SAFE"
132 PLANE SPATIAL SPA+45 SPB+0 SPC+0 STAY SEQ-
133 ;Conversion sur le plan
134 CALL LBL "TILT_NEW"
135 LBL 0
136 ;
137 * - Inclinaison 2
138 LBL "TILT2"
139 PLANE RESET STAY
140 CYCL DEF 7.0 POINT ZERO
141 CYCL DEF 7.1  X+30
142 CYCL DEF 7.2  Y-30
143 CYCL DEF 7.3  Z-5
144 CALL LBL "SAFE"
145 PLANE SPATIAL SPA+45 SPB+0 SPC+90 STAY SEQ-
146 ;Conversion sur le plan
147 CALL LBL "TILT_NEW"
148 LBL 0
149 ;
150 * - Inclinaison 3
151 LBL "TILT3"
152 PLANE RESET STAY
153 CYCL DEF 7.0 POINT ZERO
154 CYCL DEF 7.1  X+30
155 CYCL DEF 7.2  Y+30
156 CYCL DEF 7.3  Z-5
157 CALL LBL "SAFE"
158 PLANE SPATIAL SPA+45 SPB+0 SPC+180 STAY SEQ-
159 ;Conversion sur le plan
160 CALL LBL "TILT_NEW"
161 LBL 0
162 ;
163 * - Inclinaison 4
164 LBL "TILT4"
165 PLANE RESET STAY
166 CYCL DEF 7.0 POINT ZERO
167 CYCL DEF 7.1  X-30
168 CYCL DEF 7.2  Y+30
169 CYCL DEF 7.3  Z-5
170 CALL LBL "SAFE"
171 PLANE SPATIAL SPA+45 SPB+0 SPC+270 STAY SEQ-
172 ;Conversion sur le plan
173 CALL LBL "TILT_NEW"
174 LBL 0
175 ;
176 * - Position de sécurité
177 LBL "SAFE"
178 M3
179 L  Z+300 R0 FMAX M91
180 L  X+400  Y-300 R0 FMAX M91
181 LBL 0
182 ;
183 * - Réinitialisation de toutes les conversions de coordonnées
184 LBL "RESET"
185 CALL LBL "SAFE"
186 PLANE RESET TURN FMAX
187 CYCL DEF 7.0 POINT ZERO
188 CYCL DEF 7.1  X+0
189 CYCL DEF 7.2  Y+0
190 CYCL DEF 7.3  Z+0
191 CYCL DEF 8.0 IMAGE MIROIR
192 CYCL DEF 8.1
193 CYCL DEF 10.0 ROTATION
194 CYCL DEF 10.1  ROT+0
195 CYCL DEF 11.0 FACTEUR ECHELLE
196 CYCL DEF 11.1 SCL 1
197 LBL 0
198 ;
199 * - Conversion des angles
200 LBL "TILT_NEW"
201 ;Lecture de 3D-ROT
202 FN 18: SYSREAD Q170 = ID210 NR5 IDX1 ;3D-ROT SPA
203 FN 18: SYSREAD Q171 = ID210 NR5 IDX2 ;3D-ROT SPB
204 FN 18: SYSREAD Q172 = ID210 NR5 IDX3 ;3D-ROT SPC
205 PLANE RESET STAY
206 ;Lecture du décalage de point zéro
207 FN 18: SYSREAD Q175 = ID220 NR2 IDX1 ;Décalage de point zéro en X
208 FN 18: SYSREAD Q176 = ID220 NR2 IDX2 ;Décalage de point zéro en Y
209 FN 18: SYSREAD Q177 = ID220 NR2 IDX3 ;Décalage de point zéro en Z
210 ;Inclinaison de l'alignement
211 CYCL DEF 7.0 POINT ZERO
212 CYCL DEF 7.1  X+0
213 CYCL DEF 7.2  Y+0
214 CYCL DEF 7.3  Z+0
215 PLANE SPATIAL SPA+QR170 SPB+QR171 SPC+QR172 STAY
216 ;Décalage du point zéro sur la surface alignée
217 CYCL DEF 7.0 POINT ZERO
218 CYCL DEF 7.1 IX+Q175
219 CYCL DEF 7.2 IY+Q176
220 CYCL DEF 7.3 IZ+Q177
221 ;Incliner la rotation 3D (3D-ROT) dessus
222 PLANE RELATIV SPC+Q172 STAY
223 PLANE RELATIV SPB+Q171 STAY
224 CALL LBL "SAFE"
225 PLANE RELATIV SPA+Q170 TURN FMAX SEQ-
226 LBL 0
227 END PGM 4240_fr MM