0  BEGIN PGM 5085-FR MM 
1  ;Dans ce programme, un tenon circulaire
2  ;et une poche circulaire un tenon
3  ;circulaire sont usinés, puis un chanfrein
4  ;est fraisé sur leurs contours, à l'aide
5  ;d'un outil incliné. Les contours se
6  ;programment avec des cycles. Pour les
7  ;chanfreins, il vous faut utiliser les
8  ;paramètres qui ont servi à la CN pour
9  ;calculer les trajectoires de l'outil.
10 ;
11 BLK FORM 0.1 Z X-50 Y-50 Z-40
12 BLK FORM 0.2  X+50  Y+50  Z+10
13 TOOL CALL 8 Z S12000 F5000 ;Fraise D16
14 ;Inclinaison du plan d'usinage
15 PLANE SPATIAL SPA+10 SPB+0 SPC+0 TURN MB100 FMAX
16 CYCL DEF 232 FRAISAGE TRANSVERSAL ~
    Q389=+1    ;STRATEGIE ~
    Q225=-50   ;PT INITIAL 1ER AXE ~
    Q226=-60   ;PT INITIAL 2EME AXE ~
    Q227=+20   ;PT INITIAL 3EME AXE ~
    Q386=+0    ;POINT FINAL 3EME AXE ~
    Q218=+100  ;1ER COTE ~
    Q219=+120  ;2EME COTE ~
    Q202=+20   ;PROF. PLONGEE MAX. ~
    Q369=+0    ;SUREP. DE PROFONDEUR ~
    Q370=+1    ;RECOUVREMENT MAX. ~
    Q207= AUTO ;AVANCE FRAISAGE ~
    Q385= AUTO ;AVANCE DE FINITION ~
    Q253= MAX ;AVANCE PRE-POSIT. ~
    Q200=+2    ;DISTANCE D'APPROCHE ~
    Q357=+2    ;DIST. APPR. LATERALE ~
    Q204=+50   ;SAUT DE BRIDE
17 M3 M99
18 CYCL DEF 252 POCHE CIRCULAIRE ~
    Q215=+0    ;OPERATIONS D'USINAGE ~
    Q223=+60   ;DIAMETRE DU CERCLE ~
    Q368=+0    ;SUREPAIS. LATERALE ~
    Q207=+500  ;AVANCE FRAISAGE ~
    Q351=+1    ;MODE FRAISAGE ~
    Q201=-10   ;PROFONDEUR ~
    Q202=+10   ;PROFONDEUR DE PASSE ~
    Q369=+0    ;SUREP. DE PROFONDEUR ~
    Q206=+150  ;AVANCE PLONGEE PROF. ~
    Q338=+0    ;PASSE DE FINITION ~
    Q200=+2    ;DISTANCE D'APPROCHE ~
    Q203=+0    ;COORD. SURFACE PIECE ~
    Q204=+50   ;SAUT DE BRIDE ~
    Q370=+1    ;FACTEUR RECOUVREMENT ~
    Q366=+1    ;PLONGEE ~
    Q385=+500  ;AVANCE DE FINITION
19 L  X+0  Y+0 R0 FMAX M3 M99
20 CYCL DEF 257 TENON CIRCULAIRE ~
    Q223=+100  ;DIA. PIECE FINIE ~
    Q222=+142  ;DIAM. PIECE BRUTE ~
    Q368=+0    ;SUREPAIS. LATERALE ~
    Q207=+500  ;AVANCE FRAISAGE ~
    Q351=+1    ;MODE FRAISAGE ~
    Q201=-10   ;PROFONDEUR ~
    Q202=+10   ;PROFONDEUR DE PASSE ~
    Q206=+3000 ;AVANCE PLONGEE PROF. ~
    Q200=+2    ;DISTANCE D'APPROCHE ~
    Q203=+0    ;COORD. SURFACE PIECE ~
    Q204=+50   ;SAUT DE BRIDE ~
    Q370=+1    ;FACTEUR RECOUVREMENT ~
    Q376=-1    ;ANGLE INITIAL
21 L  X+0  Y+0 R0 FMAX M3 M99
22 ;
23 ;Paramètres du chanfrein
24 Q1 = 5 ;LONGUEUR DU CHANFREIN
25 Q2 = 45 ;ANGLE DU CHANFREIN
26 Q3 = 100 ;DIAMETRE DU CERCLE
27 Q4 = 1 ;USINAGE : 1=EXTERIEUR 2=INTERIEUR
28 TOOL CALL  DL-0.5 ;Dépassement pour obtenir une arête de chanfreinage inférieure nette
29 CALL LBL "fase"
30 PLANE SPATIAL SPA+10 SPB+0 SPC+0 TURN MB100 FMAX
31 ;
32 ;Paramètres du chanfrein
33 Q1 = 5 ;LONGUEUR DU CHANFREIN
34 Q2 = 45 ;ANGLE DU CHANFREIN
35 Q3 = 60 ;DIAMETRE DU CERCLE
36 Q4 = 2 ;USINAGE: 1=EXTERIEUR 2=INTERIEUR
37 TOOL CALL  DL-0.5 ;Dépassement pour obtenir une arête de chanfreinage inférieure nette
38 CALL LBL "fase"
39 ;
40 M2
41 LBL "fase"
42 ;Requête : extérieur ou intérieur
43 FN 9: IF +Q4 EQU +2 GOTO LBL "inside"
44 FN 9: IF +Q4 EQU +1 GOTO LBL "outside"
45 STOP
46 ;Veuillez sélectionner extérieur ou intérieur pour Q4
47 ;
48 LBL "inside"
49 FUNCTION TCPM F TCP AXIS SPAT PATHCTRL VECTOR
50 Q10 = Q108 * ( COS Q2 ) ;Calcul de la correction du rayon de l'outil
51 Q11 = ( Q3 / 2 ) - Q10 ;Diamètre - Correction du rayon de l'outil
52 Q12 = ( Q1 / TAN Q2 ) - ( SIN Q2 * Q108 ) ;Correction de l'outil en Z
53 QL11 = Q11 - Q108 ;Position d'approche Y
54 QL12 = Q12 - 2 ;Position d'approche Z
55 L  X-Q108  Y-QL11  Z+50 R0 FMAX
56 L  A+Q2  B+0  C+0 R0 FMAX ;Les trois axes rotatifs sont importants à cause de TCPM ... AXIS SPAT
57 L  Z-QL12 R0 F AUTO
58 CC  X+0  Y-QL11
59 CP  PA-90  Z-Q12 DR+
60 QL1 = 270
61 LBL 1
62 QL1 = QL1 + 1
63 QL2 = Q11 * COS QL1
64 QL3 = Q11 * SIN QL1
65 L  X+QL2  Y+QL3 IC+1
66 CALL LBL 1 REP359
67 CC  X+0  Y-QL11
68 CP  PA+0  Z-QL12 DR+
69 M140 MB+20
70 FN 9: IF +0 EQU +0 GOTO LBL "reset"
71 ;
72 LBL "outside"
73 FUNCTION TCPM F TCP AXIS SPAT PATHCTRL VECTOR
74 Q10 = Q108 * ( COS Q2 ) ;Calcul de la correction du rayon de l'outil
75 Q11 = ( Q3 / 2 ) + Q10 ;Diamètre + Correction du rayon de l'outil
76 Q12 = ( Q1 / TAN Q2 ) - ( SIN Q2 * Q108 ) ;Correction de l'outil en Z
77 QL11 = Q11 + Q108 ;Position d'approche en Y
78 QL12 = Q12 - 2 ;Position d'approche en Z
79 L  X+Q108  Y-QL11  Z+50 R0 FMAX
80 L  A-Q2  B+0  C+0 R0 FMAX ;Les trois axes rotatifs sont importants à cause de TCPM ... AXIS SPAT.
81 L  Z-QL12 R0 F AUTO
82 CC  X+0  Y-QL11
83 CP IPA+90  Z-Q12 DR+
84 QL1 = 270
85 LBL 2
86 QL1 = QL1 - 1
87 QL2 = Q11 * COS QL1
88 QL3 = Q11 * SIN QL1
89 L  X+QL2  Y+QL3 IC-1
90 CALL LBL 2 REP359
91 CC  X+0  Y-QL11
92 CP  PA+180  Z-QL12 DR+
93 M140 MB+20
94 ;
95 LBL "reset"
96 FUNCTION RESET TCPM
97 L  Z+500 R0 FMAX M91
98 L  X+800  Y+600 R0 FMAX M91
99 PLANE RESET TURN FMAX
100 LBL 0
101 END PGM 5085-FR MM