0 BEGIN PGM 7080_FR MM 
1 ;Programme permettant d'usiner un cône de
2 ;l'extérieur à l'aide d'une fraise deux tailles.
3 ;L'usinage se déroule avec un mouvement en X
4 ;et Z. Dans un paramètre, vous définissez la
5 ;fréquence à laquelle cette trajectoire de
6 ;fraisage doit être répétée pour fraiser le
7 ;cône en continu (Q10)
8 ;
9 BLK FORM 0.1 Z X+0 Y+0 Z-30
10 BLK FORM 0.2  X+50  Y+50  Z+0
11 ;
12 ;Définition des paramètres
13 FN 0: Q1 =+25 ;CENTRE PREMIER AXE
14 FN 0: Q2 =+25 ;CENTRE DEUXIÈME AXE
15 FN 0: Q3 =+0 ;COORDONNÉE Z EN HAUT
16 FN 0: Q5 =+15 ;RAYON EN HAUT
17 FN 0: Q4 =-20 ;COORDONNÉE Z EN BAS
18 FN 0: Q6 =+25 ;RAYON EN BAS
19 FN 0: Q7 =+2 ;DISTANCE DE SÉCURITÉ
20 FN 0: Q8 =+600 ;AVANCE FRAISAGE
21 FN 0: Q9 =+9999 ;AVANCE RETRAIT
22 FN 0: Q10 =+180 ;DIVISION
23 FN 0: Q16 =+10 ;DISTANCE DE SÉCURITÉ LATÉRALE
24 ;Fin de la définition des paramètres
25 ;
26 ;Appel de la fraise deux tailles
27 TOOL CALL 8 Z S5555
28 ;
29 ;Calculs
30 FN 1: Q11 =+Q3 + +Q7 ;Hauteur de sécurité
31 FN 1: Q12 =+Q5 + +Q108 ;Rayon compensé en haut
32 FN 1: Q13 =+Q6 + +Q108 ;Rayon compensé en bas
33 FN 1: Q17 =+Q13 + +Q16 ;Position de sécurité latérale
34 FN 4: Q14 =+360 DIV +Q10 ;Pas angulaire
35 FN 2: Q15 =+Q10 - +1 ;Nombre de répétitions
36 ;Fin des calculs
37 ;
38 L  Z+100 R0 FMAX M3 ;Dégagement
39 ;
40 ;Décalage du point zéro au centre
41 CYCL DEF 7.0 NULLPUNKT
42 CYCL DEF 7.1  X+Q1
43 CYCL DEF 7.2  Y+Q2
44 L  X+Q17  Y+0 R0 FMAX ;Pré-positionnement
45 L  Z+Q11 R0 FMAX ;Déplacement à la hauteur de sécurité
46 LBL 1
47 L  Z+Q4 R0 FQ9 ;Approche de Z en profondeur
48 L  X+Q13  Y+0 R0 FQ9 ;Approche du rayon inférieur
49 L  X+Q12  Y+0  Z+Q3 ;Déplacement sur le rayon et le bord supérieurs
50 L  Z+Q11 R0 FQ9 ;Déplacement à la hauteur de sécurité
51 L  X+Q17  Y+0 R0 ;Déplacement à la distance latérale
52 ;Pas angulaire
53 CYCL DEF 10.0 DREHUNG
54 CYCL DEF 10.1 IROT+Q14
55 CALL LBL 1 REPQ15 ;Répétition
56 ;
57 ;Réinitialisation de la conversion des coordonnées
58 CYCL DEF 10.0 DREHUNG
59 CYCL DEF 10.1  ROT+0
60 CYCL DEF 7.0 NULLPUNKT
61 CYCL DEF 7.1  X+0
62 CYCL DEF 7.2  Y+0
63 CYCL DEF 7.3  Z+0
64 ;Dégagement et fin de programme
65 L  Z+100 R0 FQ9 M30
66 END PGM 7080_FR MM