0 BEGIN PGM 7110_fr MM 
1 ;Programme permettant l'usinage extérieur
2 ;d'un hémisphère avec une fraise deux
3 ;tailles.
4 ;Le fraisage est effectué sur la
5 ;trajectoire X/Z, du bas vers le haut.
6 ;Ce mouvement est divisé en plusieurs
7 ;trajectoires linéaires. Le système de
8 ;coordonnées est alors tourné et la
9 ;trajectoire suivante est parcourue.
10 ;La précision et la qualité de la
11 ;surface sont déterminées par les
12 ;divisions définies.
13 ;
14 ;Définition des paramètres
15 FN 0: Q1 =+55 ;CENTRE DE LA BOULE SUR L'AXE X
16 FN 0: Q2 =+55 ;CENTRE DE LA BOULE SUR L'AXE Y
17 FN 0: Q3 =-50 ;CENTRE DE LA BOULE SUR L'AXE Z
18 FN 0: Q4 =+50 ;RAYON DE LA BOULE
19 FN 0: Q5 =+60 ;DIVISION DANS LE PLAN X/Y
20 ;             ;DÉFINIT EN COMBIEN DE 
21 ;             ;TRAJECTOIRES DE FRAISAGE DANS
22 ;             ;LE PLAN X/Y LES 360 DEGRÉS 
23 ;             ;SONT DIVISÉS.
24 FN 0: Q6 =+15 ;DIVISION DANS LE PLAN X/Z
25 ;             ; DÉFINIT EN COMBIEN D'ÉLEMENTS 
26 ;             ;LINÉAIRES SUR LES 
27 ;             ;AXES X, Y ET Z, LES MOUVEMENTS 
28 ;             ;3D SONT DIVISÉS.
29 FN 0: Q7 =+20 ;DISTANCE DE SÉCURITÉ LATÉRALE
30 ;             ;DISTANCE ENTRE LE CORPS ET 
31 ;             ;L'OUTIL PENDANT LE PRÉ-POSITIONNEMENT
32 FN 0: Q8 =+3 ;DISTANCE DE SÉCURITÉ EN Z
33 FN 0: Q9 =+2000 ;AVANCE DE PRÉ-POSITIONNEMENT
34 FN 0: Q10 =+500 ;AVANCE DE LA PASSE EN PROFONDEUR
35 FN 0: Q11 =+800 ;AVANCE FRAISAGE
36 ;Fin de la définition des paramètres
37 ;
38 BLK FORM 0.1 Z X+0 Y+0 Z-55
39 BLK FORM 0.2  X+110  Y+110  Z+0
40 ;
41 ;Appel de la fraise deux tailles
42 TOOL CALL 50 Z S6000
43 ;
44 ;Calculs
45 FN 4: Q15 =+360 DIV +Q5 ;Pas angulaire sur plan X/Y
46 FN 2: Q25 =+Q5 - +1 ;Nombre de répétitions sur plan X/Y
47 FN 4: Q16 =+90 DIV +Q6 ;Pas angulaire sur plan X/Z
48 FN 2: Q26 =+Q6 - +1 ;Nombre de répétitions sur plan X/Z
49 FN 1: Q17 =+Q7 + +Q4 ;Position de pré-positionnement
50 FN 1: Q18 =+Q4 + +Q8 ;Position de sécurité en Z
51 ;Fin des calculs
52 ;
53 ;Décaler le point zéro au centre de la sphère
54 CYCL DEF 7.0 NULLPUNKT
55 CYCL DEF 7.1  X+Q1
56 CYCL DEF 7.2  Y+Q2
57 CYCL DEF 7.3  Z+Q3
58 ;
59 ;Pré-positionnement
60 L  X+Q17  Y+0 R0 FMAX M3
61 L  Z+Q8 R0 FMAX
62 ;
63 L  Y+0  Z+0 R0 FQ10 ;Première plongée
64 LBL 2
65 CC  Z+0  X+Q108
66 L  Y+0 R0 FQ11
67 LP  PR+Q4  PA+90 R0 FQ11 ;Approche du contour
68 LBL 3
69 LP IPA-Q16 FQ11 ;Pas linéaire dans le plan X/Z
70 CALL LBL 3 REPQ26 ;Répétition du pas linéaire
71 L  Z+Q18 R0 FQ9 ;Déplacement à la distance de sécurité
72 L  X+Q17 R0 FQ9 ;Nouveau pré-positionnement
73 L  Z+0  Y+0 R0 FQ10
74 ;Rotation du système de coordonnées
75 CYCL DEF 10.0 DREHUNG
76 CYCL DEF 10.1 IROT+Q15
77 CALL LBL 2 REPQ25 ;Répétition de la trajectoire circulaire
78 ;Réinitialisation des conversions de coordonnées
79 CYCL DEF 10.0 DREHUNG
80 CYCL DEF 10.1  ROT+0
81 CYCL DEF 7.0 NULLPUNKT
82 CYCL DEF 7.1  X+0
83 CYCL DEF 7.2  Y+0
84 CYCL DEF 7.3  Z+0
85 ;Dégagement et fin de programme
86 L  Z+100 R0 FMAX M30
87 END PGM 7110_fr MM