0 BEGIN PGM 7115_fr MM 
1 ;Programme permettant l'usinage extérieur
2 ;d'un hémisphère avec une fraise torique.
3 ;Le fraisage est effectué sur la trajectoire
4 ;X/Z, du bas vers le haut. Ce mouvement est
5 ;divisé en plusieurs trajectoires linéaires.
6 ;Le système de coordonnées est alors tourné
7 ;et la trajectoire suivante est parcourue.
8 ;La précision et la qualité de la surface
9 ;sont déterminées par les divisions définies.
10 ;
11 ;Définition des paramètres
12 FN 0: Q1 =+50 ;CENTRE DE LA BOULE SUR L'AXE X
13 FN 0: Q2 =+50 ;CENTRE DE LA BOULE SUR L'AXE Y
14 FN 0: Q3 =-45 ;CENTRE DE LA BOULE SUR L'AXE Z
15 FN 0: Q4 =+45 ;RAYON DE LA BOULE
16 FN 0: Q5 =+60 ;DIVISION DANS LE PLAN X/Y
17 ;             ;; DÉFINIT EN COMBIEN DE 
18 ;             ;TRAJECTOIRES DE FRAISAGE DANS 
19 ;             ;LE PLAN X/Y LES 360 DEGRÉS 
20 ;             ;SONT DIVISÉS.
21 FN 0: Q6 =+15 ;DIVISION DANS LE PLAN X/Z
22 ;             ;DÉFINIT EN COMBIEN D'ÉLEMENTS 
23 ;             ;LINÉAIRES SUR LES AXES X, Y 
24 ;             ;ET Z, LES MOUVEMENTS 3D SONT 
25 ;             ;DIVISÉS.
26 FN 0: Q7 =+20 ;DISTANCE DE SÉCURITÉ LATÉRALE
27 ;             ;DISTANCE ENTRE LE CORPS ET 
28 ;             ;L'OUTIL PENDANT LE
29 ;             ;PRÉ-POSITIONNEMENT
30 FN 0: Q8 =+3 ;DISTANCE DE SÉCURITÉ EN Z
31 FN 0: Q9 =+2000 ;AVANCE DE PRÉ-POSITIONNEMENT
32 FN 0: Q10 =+500 ;AVANCE DE LA PASSE EN PROFONDEUR
33 FN 0: Q11 =+800 ;AVANCE FRAISAGE
34 FN 0: Q12 =+5 ;Rayon de la dent d'outil
35 ;Fin de la définition des paramètres
36 ;
37 BLK FORM 0.1 Z X+0 Y+0 Z-55
38 BLK FORM 0.2  X+100  Y+100  Z+0
39 ;
40 ;Appel de la fraise torique
41 TOOL CALL 119 Z S8000 DL-Q12
42 ;
43 ;Calculs
Q21 = Q108 - Q12 ;Calcul du rayon de la dent
44 FN 1: Q19 =+Q4 + +Q12 ;Calcul du rayon de la dent
45 FN 4: Q15 =+360 DIV +Q5 ;Pas angulaire sur plan X/Y
46 FN 2: Q25 =+Q5 - +1 ;Nombre de répétitions sur plan X/Y
47 FN 4: Q16 =+90 DIV +Q6 ;Pas angulaire sur plan X/Z
48 FN 2: Q26 =+Q6 - +1 ;Nombre de répétitions sur plan X/Z
49 FN 1: Q17 =+Q7 + +Q4 ;Position de pré-positionnement
50 FN 1: Q18 =+Q4 + +Q8 ;Position de sécurité en Z
51 FN 1: Q18 =+Q18 + +Q12 ;Position de sécurité en Z
52 ;Fin des calculs
53 ;
54 ;Décaler le point zéro au centre de la sphère
55 CYCL DEF 7.0 NULLPUNKT
56 CYCL DEF 7.1  X+Q1
57 CYCL DEF 7.2  Y+Q2
58 CYCL DEF 7.3  Z+Q3
59 ;
60 ;Pré-positionnement
61 L  X+Q17  Y+0 R0 FMAX M3
62 L  Z+Q18 R0 FMAX
63 ;
64 L  Y+0  Z+0 R0 FQ10 ;Première plongée
65 LBL 2
66 CC  Z+0  X+Q21
67 L  Y+0 R0 FQ11
68 LP  PR+Q19  PA+90 R0 FQ11 ;Approche du contour
69 LBL 3
70 LP IPA-Q16 R0 FQ11 ;Pas linéaire dans le plan X/Z
71 CALL LBL 3 REPQ26 ;Répétition du pas linéaire
72 L  Z+Q18 R0 FQ9 ;À une distance de sécurité
73 L  X+Q17 R0 FQ9 ;Nouveau pré-positionnement
74 L  Y+0  Z+0 R0 FQ10
75 ;Rotation du système de coordonnées
76 CYCL DEF 10.0 DREHUNG
77 CYCL DEF 10.1 IROT+Q15
78 CALL LBL 2 REPQ25 ;Répétition de la trajectoire circulaire
79 ;Réinitialisation de la conversion des coordonnées
80 CYCL DEF 10.0 DREHUNG
81 CYCL DEF 10.1  ROT+0
82 CYCL DEF 7.0 NULLPUNKT
83 CYCL DEF 7.1  X+0
84 CYCL DEF 7.2  Y+0
85 CYCL DEF 7.3  Z+0
86 ;Dégagement et fin de programme
87 L  Z+100 R0 FMAX M30
88 END PGM 7115_fr MM