0 BEGIN PGM 7125_fr MM 
1 ;Programme permettant l'usinage extérieur
2 ;d'un hémisphère avec une fraise torique.
3 ;L'usinage se déroule par un mouvement en
4 ;spirale. Ce mouvement est divisé en
5 ;fonction de chacun des mouvements linéaires.
6 ;Les divisions définissent en combien de
7 ;mouvements linéaires la trajectoire est
8 ;divisée et influencent ainsi la précision.
9 ;
10 BLK FORM 0.1 Z X-30 Y-30 Z-40
11 BLK FORM 0.2  X+30  Y+30  Z+0
12 ;
13 ;Définition des paramètres
14 FN 0: Q1 =+0 ;CENTRE DE LA BOULE SUR L'AXE X
15 FN 0: Q2 =+0 ;CENTRE DE LA BOULE SUR L'AXE Y
16 FN 0: Q3 =-30 ;CENTRE DE LA BOULE SUR L'AXE Z
17 FN 0: Q4 =+45 ;DIVISION VERTICALE
18 ;             ; DÉFINIT COMBIEN DE TRAJECTOIRES 
19 ;             ;EN SPIRALE DE 360 DEGRÉS SONT 
20 ;             ;PARCOURUES DE HAUT EN BAS
21 FN 0: Q5 =+180 ;DIVISION HORIZONTALE
22 ;              ; DÉFINIT EN COMBIEN DE TRAJECTOIRES 
23 ;              ;LINÉAIRES UNE TRAJECTOIRE CIRCULAIRE 
24 ;              ;DE 360 DEGRÉS EST DIVISÉE.
25 FN 0: Q6 =+30 ;RAYON DE LA BOULE
26 FN 0: Q7 =+90 ;ANGLE DE DÉPART À LA VERTICALE
27 FN 0: Q8 =+0 ;ANGLE DE DÉPART DANS LE PLAN X/Y
28 FN 0: Q10 =+150 ;AVANCE DE LA PASSE EN PROFONDEUR
29 FN 0: Q11 =+1000 ;AVANCE DE LA TRAJECTOIRE HÉLICOÏDALE
30 FN 0: Q13 =+3 ;RAYON DE LA DENT D'OUTIL
31 FN 0: Q15 =+2 ;DISTANCE DE SÉCURITÉ
32 FN 0: Q17 =+0 ;ANGLE FINAL À LA VERTICALE
33 ;Fin de la définition des paramètres
34 ;
35 ;Appel de la fraise torique
36 TOOL CALL 112 Z S3000 DL-Q13
37 ;
38 ;Pré-positionnement
39 L  X+Q1  Y+Q2 R0 FMAX M3
40 FN 1: Q16 =+Q15 + +Q13
41 L  Z+Q16 FMAX
42 CALL LBL 1 ;Appel du mouvement hélicoïdal
43 ;
44 ;Fin du programme
45 L  Z+100 R0 FMAX M30
46 ;
47 ;Mouvement en spirale
48 LBL 1
Q14 = Q108 - Q13 ;Calcul du rayon de l'outil
Q26 = Q6 + Q13 ;Rayon effectif jusqu'au centre de la denture
49 FN 0: Q27 =+Q7 ;Angle actuel vertical = angle de départ vertical
50 FN 0: Q28 =+Q8 ;Angle actuel sur le plan X/Y =angle de départ du plan X/Y
Q37 = ( Q17 - Q7 ) / Q4 / Q5 ;Pas angulaire vertical
Q38 = - 360 / Q5 ;Pas angulaire sur plan X/Y
51 CALL LBL 10
52 L  X+Q21  Y+Q22  Z+Q23 R0 FQ10 ;Déplacer en 1re position
53 ;
54 ;Appel des calculs, comparaison d'angles et à
55 ;la fin, de la trajectoire circulaire complète
56 LBL 2
57 CALL LBL 10
58 L  X+Q21  Y+Q22  Z+Q23 FQ11
59 FN 11: IF +Q27 GT +Q17 GOTO LBL 2
60 CC  X+Q1  Y+Q2
61 CP IPA-360 DR- FQ11
62 LBL 0
63 ;
64 ;Calcul de la position X,Y,Z et du nouvel angle
65 LBL 10
Q20 = COS Q27 * Q26 + Q14
Q21 = COS Q28 * Q20 + Q1
Q22 = SIN Q28 * Q20 + Q2
Q23 = SIN Q27 * Q26 + Q3
Q27 = Q27 + Q37
Q28 = Q28 + Q38
66 LBL 0
67 END PGM 7125_fr MM