0  BEGIN PGM 8090-fr MM 
1  ;Programme permettant d'acqurir des points
2  ;de coordonnes.
3  ;
4  BLK FORM 0.1 Z  X+0  Y+0  Z-20
5  BLK FORM 0.2  X+100  Y+100  Z+0
6  ;
7  ;Inscription de BeginPGM dans le rapport
8  FN 16: F-PRINT BeginPGM.A / surface_data.txt
9  ;
10 ;Appel du palpeur
11 TOOL CALL 501 Z
12 ;
13 ;Prpositionnement
14 FN 0: Q1 =+0 ;COORDONNEE DE DEPART EN X POUR LE PREPOSITIONNEMENT
15 FN 0: Q2 =+0.5 ;COORDONNEE DE DEPART EN Y
16 LBL 1
17 FN 1: Q1 =+Q1 + +5 ;Nouvelle valeur en X=valeur actuelle+pas
18 TCH PROBE 0.0 PLAN DE REFERENCE Q3 Z-
19 TCH PROBE 0.1  X+Q1  Y+Q2  Z+5
20 ;
21 ;Inscription des valeurs dans le rapport
22 FN 16: F-PRINT measure.A / surface_data.txt
23 CALL LBL 1 REP18 ;18 rptitions, dernire coordonne X+95
24 FN 1: Q2 =+Q2 + +1 ;Pas en Y
25 LBL 2
26 TCH PROBE 0.0 PLAN DE REFERENCE Q3 Z-
27 TCH PROBE 0.1  X+Q1  Y+Q2  Z+5
28 ;
29 ;Inscription des valeurs dans le rapport
30 FN 16: F-PRINT measure.A / surface_data.txt
31 FN 2: Q1 =+Q1 - +5 ;Pas en X
32 CALL LBL 2 REP18 ;18 rptitions, dernire coordonne X+5
33 FN 1: Q2 =+Q2 + +1 ;Pas en Y
34 CALL LBL 1 REP49 ;49 rptitions, dernire ligne X+99,5
35 ;
36 ;Inscription de EndPGM dans le rapport
37 FN 16: F-PRINT ENDPGM.A / surface_data.txt
38 ;
39 ;Fin du programme
40 L  Z+100 R0 FMAX M30
41 END PGM 8090-fr MM