0  BEGIN PGM 82251_FR MM 
1  ;Programme CN permettant de poursuivre le
2  ;comptage, de lire l'heure actuelle et de
3  ;comparer l'heure que vous avez définie
4  ;dans le programme 8220_fr.h.
5  ;Si l'heure que vous avez définie est
6  ;atteinte ou dépassée, la CN remet
7  ;automatiquement le compteur à zéro.
8  ;
9  ;Incrémentation de la valeur du compteur de un
10 QR1 = QR1 + 1
11 ;
12 ;Lecture de l'heure actuelle et mémorisation au
13 ;paramètre QS1
14 QS1 = SYSSTR( ID321 NR13 )
15 ;
16 ;Séparation des heures du paramètre QS1 et mémorisation
17 ;au paramètre QS20
18 QS20 = SUBSTR( SRC_QS1 BEG0 LEN2 )
19 ;
20 ;Séparation des minutes du paramètre QS1 et
21 ;mémorisation au paramètre QS21
22 QS21 = SUBSTR( SRC_QS1 BEG3 LEN2 )
23 ;
24 ;Conversion de la valeur du paramètre QS20 en
25 ;valeur numérique et mémorisation au paramètre
26 ;QL20 (heures)
27 QL20 = TONUMB( SRC_QS20 )
28 ;
29 ;Conversion de la valeur du paramètre QS21 en valeur
30 ;numérique et mémorisation au paramètre QL21 (minutes)
31 QL21 = TONUMB( SRC_QS21 )
32 ;
33 ;Contrôle si les heures définies pour la réinitialisation
34 ;ont été atteintes
35 FN 11: IF +QL20 GT +QR10 GOTO LBL "RESET"
36 FN 12: IF +QL20 LT +QR10 GOTO LBL "NOT_RESET"
37 ;
38 ;Contrôle si les minutes définies pour la réinitialisation
39 ;ont été atteintes
40 FN 12: IF +QL21 LT +QR11 GOTO LBL "NOT_RESET"
41 ;
42 ;Réinitialisation du compteur
43 LBL "RESET"
44 QR1 = 0
45 ;
46 STOP
47 LBL "NOT_RESET"
48 END PGM 82251_FR MM