0  BEGIN PGM 8230_FR MM 
1  ;Programme CN permettant de mesurer
2  ;avec précision la coordonnée Z de
3  ;différentes positions d'usinage
4  ;définies dans un tableau de points
5  ;et de les enregistrer dans ce même
6  ;tableau. Le tableau de points est
7  ;ensuite défini comme motif : la CN
8  ;exécute alors un cycle d'usinage
9  ;donné aux différentes positions.
10 ;La coordonnée Z entrée dans le
11 ;tableau définit le point de départ
12 ;du cycle de manière à ce que la
13 ;profondeur définie se réfère
14 ;toujours à la coordonnée Z
15 ;préalablement mesurée.
16 ;
17 BLK FORM 0.1 Z X-25 Y-25 Z-50
18 BLK FORM 0.2  X+25  Y+25  Z+0
19 ;
20 ;Mesure
21 ;Appel de l'outil Palpeur
22 TOOL CALL "TOUCH_PROBE" Z
23 ;
24 ;Ouverture du tableau
25 FN 26: TABOPEN 82301_fr.PNT
26 ;
27 Q52 = 5 ;NOMBRE DE POSITIONS A MESURER
28 CALL LBL "MEASURE" ;Appel du sous-programme Mesure
29 ;
30 ;Edition
31 ;Appel d'outil : foret
32 TOOL CALL "DRILL_D8.5" Z S9000 F2500
33 M3
34 CYCL DEF 200 PERCAGE ~
    Q200=+2    ;DISTANCE D'APPROCHE ~
    Q201=-2    ;PROFONDEUR ~
    Q206= AUTO ;AVANCE PLONGEE PROF. ~
    Q202=+5    ;PROFONDEUR DE PASSE ~
    Q210=+0    ;TEMPO. EN HAUT ~
    Q203=+0    ;COORD. SURFACE PIECE ~
    Q204=+50   ;SAUT DE BRIDE ~
    Q211=+0    ;TEMPO. AU FOND ~
    Q395=+1    ;REFERENCE PROFONDEUR
35 SEL PATTERN "82301_fr.PNT"
36 L  X+0  Y+0  Z+50 R0 FMAX
37 CYCL CALL PAT FMAX
38 ;
39 CALL LBL "SAFE" ;Approche de la position de sécurité
40 ;
41 ;Fin du programme
42 M30
43 ;
44 ;Sous-programmes
45 ;Approche de la position de sécurité
46 LBL "SAFE"
47 M140 MB MAX F9999
48 L  X+0  Y+0 R0 FMAX M91
49 LBL 0
50 ;
51 ;Sous-programme Mesure
52 LBL "MEASURE"
53 Q50 = 0 ;Première ligne
54 Q51 = Q52 - 1 ;Calcul du nombre de répétitions
55 LBL "LOOP"
56 ;Lecture des coordonnées XY pour la mesure
57 FN 28: TABREAD Q55 =Q50 /"X,Y"
58 TCH PROBE 427 MESURE COORDONNEE ~
    Q263=+Q55  ;1ER POINT 1ER AXE ~
    Q264=+Q56  ;1ER POINT 2EME AXE ~
    Q261=+0    ;HAUTEUR DE MESURE ~
    Q320=+5    ;DISTANCE D'APPROCHE ~
    Q272=+3    ;AXE DE MESURE ~
    Q267=-1    ;SENS DEPLACEMENT ~
    Q260=+15   ;HAUTEUR DE SECURITE ~
    Q281=+0    ;PROCES-VERBAL MESURE ~
    Q288=+0    ;COTE MAX. ~
    Q289=+0    ;COTE MIN. ~
    Q309=+0    ;ARRET PGM SI ERREUR ~
    Q330=+0    ;OUTIL ~
    Q498=+0    ;INVERSER OUTIL ~
    Q531=+0    ;ANGLE DE REGLAGE
59 ;Enregistrement du résultat de la mesure en Z dans le
60 ;fichier de points
61 FN 27: TABWRITE Q50 /"Z" = Q160
62 Q50 = Q50 + 1 ;Incrémentation du numéro de ligne
63 CALL LBL "LOOP" REPQ51
64 LBL 0
65 END PGM 8230_FR MM